2

ODS PDF を使用して単純な PDF レポートを作成していますが、PDF ファイルのテーブル間にスペースを挿入するのに問題があります。これまでのコードは次のとおりです。

ODS PDF FILE = "test.pdf" STARTPAGE = NEVER;

DATA CLINIC;
   INPUT ID     $ 1-3
         GENDER $   4
         RACE   $   5
         HR       6-8
         SBP      9-11
         DBP     12-14
         N_PROC  15-16;
   AVE_BP = DBP + (SBP - DBP)/3;
DATALINES;
001MW08013008010
002FW08811007205
003MB05018810002
004FB   10806801
005MW06812208204
006FB101   07404
007FW07810406603
008MW04811207006
009FB07719011009
010FB06616410610
;


ODS PDF TEXT = "MEANS PROCEDURE FOR EVERYONE";
PROC MEANS DATA=CLINIC N STD MEAN;
    VAR SBP DBP;
RUN;

ODS PDF TEXT = "TEXT FOR ANALYSIS GOES HERE";

* Vertical space should be inserted here;

ODS PDF TEXT = "MEANS PROCEDURE FOR MEN ONLY";
PROC MEANS DATA=CLINIC N STD MEAN;
    WHERE GENDER = "M";
    VAR SBP DBP;
RUN;
ODS PDF TEXT = "TEXT FOR ANALYSIS GOES HERE";

ODS PDF CLOSE;

表を削除STARTPAGE = NEVER;すると別のページに表示されることはわかっていますが、これらは短い表であるため、小さな表をそれぞれ別のページに表示するのは意味がありません。

コメントが示すファイルに垂直方向のスペースを挿入しようとしています(最初のテーブルの後のテキストと最初のテーブルの前のテキストの間)。これどうやってするの？

4

1 に答える 1

3

次のような改行を追加するだけです。

ods pdf text="^{newline 1}";

は1、追加する空白の行数に置き換えることができます。

これは、あなたのエスケープ文字が私のものと同じであると仮定しています。そうでない場合は、次のように設定します。

ods escapechar="^";
于 2012-09-24T00:33:30.713 に答える