perl - ハッシュマージ/連結

Question

これは私のハッシュのダンプです: %hash1

$VAR1 = {
    abc => {
        123 => [
          'xx',
          'yy',
          'zy'
        ],
        456 => [
          'ab',
          'cd',
          'ef'
        ]
    }
};

2 つ目: %hash2

$VAR2 = { 
    def => {
        659 => [
            'wx',
            'yg',
            'kl'
        ],
        456 => [
            'as',
            'sd',
            'df'
        ]
    },
    abc => {
        987 => [
            'lk',
            'dm',
            'sd'
        ]
    }
};

これらの 2 つのハッシュを新しいハッシュにマージしたいのですが、キーが重複している場合 (ここでは「abc」)、値を置き換えるのではなく追加する必要があるため、キーは一意のままにし、すべての値を次のように保持する必要があります。良い。これはPerlでどのように行うことができますか? 出力は次のようになります。

$VAR1 = {
    def => {
        659 => [
            'wx',
            'yg',
            'kl'
        ],
        456 => [
            'as',
            'sd',
            'df'
        ]
    },
    abc => {
        987 => [
            'lk',
            'dm',
            'sd'
        ],
        123 => [
            'xx',
            'yy',
            'zy'
        ],
        456 => [
            'ab',
            'cd',
            'ef'
        ]
    }
 };

Answer 1

CPAN モジュールHash::Mergeまたはを使用しますHash::Merge::Simple。前者は高度な設定が可能で、後者は非常に使いやすいです。

Answer 2

for my $x (keys(%h2)) {
    for my $y (keys(%{ $h2{$x} })) {
        push @{ $h1{$x}{$y} }, @{ $h2{$x}{$y} };
    }
}

Answer 3

提供されたサンプルデータの場合、次のようにして、説明したマージが実行されます。

my %merged = map {
               $_ => {
                       %{$a{$_} // {}},
                       %{$b{$_} // {}}
                     }
             } ( keys %a, keys %b );

テスト：

use strict;
use warnings;
use Data::Dump 'dd';

my %a = (
abc => {
        123 => [
          'xx',
          'yy',
          'zy'
        ],
        456 => [
          'ab',
          'cd',
          'ef'
        ]
    }
);
my %b = (
def => {
        659 => [
            'wx',
            'yg',
            'kl'
        ],
        456 => [
            'as',
            'sd',
            'df'
        ]
    },
    abc => {
        987 => [
            'lk',
            'dm',
            'sd'
        ]
    }
);

my %merged = map {
                   $_ => {
                           %{$a{$_} // {}},
                           %{$b{$_} // {}}
                         }
                 } ( keys %a, keys %b );

dd \%merged;
# {
#   abc => {
#            123 => ["xx", "yy", "zy"],
#            456 => ["ab", "cd", "ef"],
#            987 => ["lk", "dm", "sd"],
#          },
#   def => { 456 => ["as", "sd", "df"], 659 => ["wx", "yg", "kl"] },
# }

Answer 4

sub merge_hashes {
    my ($h1, $h2) = @_;
    foreach my $key (keys %$h2) {
        if (!exists $h1->{$key} || ref($h1->{$key}) ne 'HASH' || ref($h2->{$key}) ne 'HASH') {

            $h1->{$key} = $h2->{$key};
        }
        else {
            merge_hashes($h1->{$key}, $h2->{$key});
        }
    }
}

merge_hashes(\%hash1, \%hash2);