6

これは、xml のスニペットです。

<sample>
        <test>
            <Cell1>John</Cell1>
            <Cell2>A</Cell2>
            <Cell4>xy</Cell4>
        </test>
        <test>
            <Cell1>Jack</Cell1>
            <Cell2>B</Cell2>
            <Cell3>Red</Cell3>
            <Cell6>10</Cell6>
        </test>
        <test>
            <Cell1>John,Jade</Cell1>
            <Cell2>A,Y</Cell2>
            <Cell4>1</Cell4>
        </test>
        <test>
            <Cell1>John,Jade</Cell1>
            <Cell2>A B,X</Cell2>
            <Cell3>Blue</Cell3>
        </test>
    </sample>

条件：

Cell2コンマが含まれている場合は値を分割し、前Cell2に同じ値が含まれているかどうかを確認し、同様Cell2にスペースが含まれている場合は値を分割し、前Cell2に同じ値が含まれているかどうかを確認します->そうであれば無視します。

これは私が出力を望む方法です：

<Cell2>A</Cell2>
<Cell2>B</Cell2>
<Cell2>Y</Cell2>
<Cell2>X</Cell2>

これは私が書いた xslt です: (コメントを見てください)

<xsl:template match="sample">
        <xsl:for-each select="test">
                <xsl:choose>
                    <xsl:when test="contains(Cell2,',')">
                        <xsl:variable name="token1Cell2" select="tokenize(Cell2,',')"/>
                        <xsl:for-each select="$token1Cell2">
                            <xsl:choose>
                                <xsl:when test="contains(.,' ')">
                                    <xsl:variable name="token2Cell2" select="tokenize(.,' ')"/>
                                    <xsl:for-each select="$token2Cell2">
              <!-- I tried to check if the preceding sibling element test/Cell2 contains the text that is not equal to the current text. But I know what I am doing is wrong as I am inside for-each tokenize. How to get the preceding-sibling? -->
                                      <xsl:if test="preceding-sibling::test/
Cell2/text() != '.'">
                                        <Cell2>
                                            <xsl:value-of select="."/>
                                        </Cell2>
                                        </xsl:if>
                                    </xsl:for-each>
                                </xsl:when>
                                <xsl:otherwise>
                                <xsl:if test="preceding-sibling::test/Cell2/text() != '.'">
                                    <Cell2>
                                        <xsl:value-of select="."/>
                                    </Cell2>
                                </xsl:if>
                                </xsl:otherwise>
                            </xsl:choose>
                        </xsl:for-each>
                    </xsl:when>
                    <xsl:otherwise>
                        <Cell2>
                            <xsl:value-of select="Cell2"/>
                        </Cell2>
                    </xsl:otherwise>
                </xsl:choose>
        </xsl:for-each>
    </xsl:template>

どうすれば出力を達成できますか? 何か案は？？

4

3 に答える 3

6

この単純な変換だけです:

<xsl:stylesheet version="2.0"   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
     <xsl:for-each select="distinct-values(/*/test/Cell2/tokenize(.,'[ ,]'))">
      <Cell2><xsl:value-of select="."/></Cell2>
     </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

提供された XML ドキュメントに適用した場合:

<sample>
    <test>
        <Cell1>John</Cell1>
        <Cell2>A</Cell2>
        <Cell4>xy</Cell4>
    </test>
    <test>
        <Cell1>Jack</Cell1>
        <Cell2>B</Cell2>
        <Cell3>Red</Cell3>
        <Cell6>10</Cell6>
    </test>
    <test>
        <Cell1>John,Jade</Cell1>
        <Cell2>A,Y</Cell2>
        <Cell4>1</Cell4>
    </test>
    <test>
        <Cell1>John,Jade</Cell1>
        <Cell2>A B,X</Cell2>
        <Cell3>Blue</Cell3>
    </test>
</sample>

必要な正しい結果が生成されます。

<Cell2>A</Cell2>
<Cell2>B</Cell2>
<Cell2>Y</Cell2>
<Cell2>X</Cell2>

説明:

selectの属性の XPath 式は、xsl:for-each理解するための鍵です。

distinct-values(/*/test/Cell2/tokenize(.,'[ ,]'))

これにより、トークン化されたすべてのシーケンスの個別の値 (の文字列値) が生成されます。/*/test/Cell2

于 2012-09-27T14:47:43.703 に答える
4

まず、カンマまたはスペースのいずれかでトークン化する場合、トークン化を 1 つの式に組み合わせることができます。

<xsl:for-each select="tokenize(., ',|\s')">

あなたができることは、最初にすべてのCell2要素を照合し、テンプレートで内容をトークン化し、結果を変数に入れることです

  <xsl:variable name="cells">
     <xsl:apply-templates select="test/Cell2"/>
  </xsl:variable>

次に、単にxsl:for-each-groupを使用してそれらを反復することができます

  <xsl:for-each-group select="$cells/Cell2" group-by="text()">
     <xsl:copy-of select="."/>
  </xsl:for-each-group>

ここに完全な XSLT があります

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>
   <xsl:template match="sample">
      <xsl:variable name="cells">
         <xsl:apply-templates select="test/Cell2"/>
      </xsl:variable>
      <xsl:for-each-group select="$cells/Cell2" group-by="text()">
         <xsl:copy-of select="."/>
      </xsl:for-each-group>
   </xsl:template>

   <xsl:template match="Cell2">
      <xsl:for-each select="tokenize(., ',|\s')">
         <Cell2>
            <xsl:value-of select="."/>
         </Cell2>
      </xsl:for-each>
   </xsl:template>
</xsl:stylesheet>

サンプル XML に適用すると、次のように出力されます。

<Cell2>A</Cell2>
<Cell2>B</Cell2>
<Cell2>Y</Cell2>
<Cell2>X</Cell2>
于 2012-09-27T10:56:57.277 に答える
2

xsl:for-each 命令が深くネストされている場合、各レベルでコンテキスト アイテムが変化するため、コンテキスト アイテムに戻るために各レベルで変数をコンテキスト アイテムにバインドする必要があることがよくあります。ただし、深くネストされた xsl:for-each 命令は、コードを小さなテンプレートまたは関数に分割する必要があることを示している場合があります。

于 2012-09-27T13:53:41.880 に答える