awk - 2列目に2文字のファイル名をawkで出力します

Question

2列目に2文字のファイル名をすべて印刷したいのですが。どうすればawkでこれを行うことができますか？

AA.txt

REM  A   7   35.32  
REM  A   8    47.17                         
REM  B   9    988.62                                
REM  D  10   111.59

BB.txt

REM  A   7    135.32                                           
REM  A   8    647.19                         
REM  B   9    88.62 

CC.txt

REM  A   7    135.32                                           
REM  A   8    247.17                         
REM  B   9    188.62                                
REM  B  10    111.56   

希望する出力

BB.txt
CC.txt

あなたの提案をいただければ幸いです！

Answer 1

for i in *.txt; do
    if [ $(awk '{ print $2 }' $i | sort -u | wc -l) -eq 2 ]; then
        echo $i
    fi
done

Answer 2

のみを使用する一方向GNU awk：

awk '
    ## A function that prints the file name if only found two different strings
    ## in the second field.
    function check_col_and_print_file(c, i) {
        if ( length(c) == 2 ) {
            printf "%s\n", ARGV[ i ];
        }
    }

    ## At the beginning of each file but the first one, call the function to
    ## check if the file must be printed, and reset the array for the processing
    ## of the next file (the current one because we already are in first line).
    FNR == 1 && NR > 1 { 
        check_col_and_print_file(cols, ARGIND-1);
        delete cols; 
    } 

    ## Save second field as a key of a hash to avoid repeated values.
    {
        cols[ $2 ] = 1;
    }

    ## Same as before but in the "END" block because we finished the processing
    ## of all input files.
    END {
        check_col_and_print_file(cols, ARGIND);
    }
' AA.txt BB.txt CC.txt

その結果、次のようになります。

BB.txt
CC.txt