2

私はしばらくの間これを解決する方法を見つけようとしてきましたが、成功しませんでした。私は2つのテーブルを持っています：

1）質問

ID (pk)
QUES
ORD

2）回答

ID (pk)
QUES_ID (fk)
SURV_ID (fk)
ANSW

次に、ビューを作成する必要があります。質問は列名であり、各SURV_IDについて、ANSWERSにエントリがない場合は回答NULL、エントリがある場合は回答ANSWの行がビューにあります。JOINでそれが可能かどうかわからない。

CURSORを使用して、結果のテーブルのUNIONを実行し、次にPIVOTを使用することを考えていましたが、それが最善の解決策かどうかはわかりません+ループを介して結合を実行する方法がわかりません...

DECLARE @survID int
DECLARE db_cursor CURSOR FOR
SELECT DISTINCT SURV_ID FROM ANSWERS ORDER BY SURV_ID
OPEN db_cursor
FETCH NEXT FROM db_cursor INTO @survID

WHILE @@FETCH_STATUS = 0
BEGIN
SELECT QUES
,ANSW , SURV_ID
FROM QUESTIONS a
left outer JOIN ANSWERS b ON a.ID = b.QUES_ID
WHERE ( SURV_ID = @survID OR SURV_ID IS NULL)
FETCH NEXT FROM db_cursor INTO @survID
END
CLOSE db_cursor
DEALLOCATE db_cursor

...。

更新：私が直面している問題はもう少し複雑です。すべての質問に回答があるわけではなく（その場合はNULLを表示できます）、回答はSURV_IDによってグループ化されます。 

CREATE TABLE [QUESTIONS] (
    [ID] [int] IDENTITY(1,1) NOT NULL,
    [QUES] [varchar](250) NOT NULL,
    [ORD] [int] NOT NULL,
CONSTRAINT [PK_QUESTIONS] PRIMARY KEY CLUSTERED 
(
    [ID] ASC
)WITH (PAD_INDEX  = OFF, STATISTICS_NORECOMPUTE  = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS  = ON, ALLOW_PAGE_LOCKS  = ON) ON [PRIMARY]
) ON [PRIMARY]

GO

INSERT INTO [QUESTIONS] values ('First Question', 1)
INSERT INTO [QUESTIONS] values ('Second Question', 2)

GO

CREATE TABLE [ANSWERS] (
    [ID] [int] IDENTITY(1,1) NOT NULL,
    [SURV_ID] [int] NOT NULL,
    [QUES_ID] [int] NOT NULL,
    [ANSW] [varchar](500) NOT NULL,
CONSTRAINT [PK_ANSWERS] PRIMARY KEY CLUSTERED 
(
    [ID] ASC
)WITH (PAD_INDEX  = OFF, STATISTICS_NORECOMPUTE  = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS  = ON, ALLOW_PAGE_LOCKS  = ON) ON [PRIMARY]
) ON [PRIMARY]

GO

SET ANSI_PADDING OFF
GO

ALTER TABLE [ANSWERS]  WITH CHECK ADD  CONSTRAINT [FK_ANSWERS_QUESTIONS] FOREIGN KEY([QUES_ID])
REFERENCES [QUESTIONS] ([ID])
GO

ALTER TABLE [ANSWERS]   CHECK CONSTRAINT [FK_ANSWERS_QUESTIONS]
GO


INSERT INTO [ANSWERS] ([SURV_ID],[QUES_ID],[ANSW]) VALUES (1,1,'Y')
INSERT INTO [ANSWERS] ([SURV_ID],[QUES_ID],[ANSW]) VALUES (1,2,'N')
INSERT INTO [ANSWERS] ([SURV_ID],[QUES_ID],[ANSW]) VALUES (2,1,'N')
INSERT INTO [ANSWERS] ([SURV_ID],[QUES_ID],[ANSW]) VALUES (3,2,'Y')
INSERT INTO [ANSWERS] ([SURV_ID],[QUES_ID],[ANSW]) VALUES (4,1,'Y')
INSERT INTO [ANSWERS] ([SURV_ID],[QUES_ID],[ANSW]) VALUES (4,2,'Y')
GO

私が欲しいのは、 

[SURV_ID]          [First Question]          [Second Question]  
1                  Y                         N  
2                  N                         null  
3                  null                      Y  
4                  Y                         Y
4

1 に答える 1

2

SQL-Serverで作業しているように見えるので、次のように動作するはずです。変換するアイテムの数がわかっている場合は、値をハードコーディングできます。

select *
from
(
  select a.surv_id,
    a.answ,
    q.ques
  from QUESTIONS q
  left join ANSWERS a
    on q.ID = a.QUES_ID
) x
pivot
(
  max(answ)
  for ques in ([First Question], [Second Question])
) p

SQL FiddleWithDemoを参照してください

列の数がわからない場合は、動的SQLを使用できます。

DECLARE @query  AS NVARCHAR(MAX),
    @colsPivot as  NVARCHAR(MAX)

select @colsPivot = STUFF((SELECT distinct  ',' 
                      + quotename(ques)
                    from QUESTIONS 
            FOR XML PATH(''), TYPE
            ).value('.', 'NVARCHAR(MAX)') 
        ,1,1,'')

set @query 
  = 'select *
     from 
     (
        select a.surv_id,
          a.answ,
          q.ques
        from QUESTIONS q
        left join ANSWERS a
          on q.ID = a.QUES_ID
      ) x
      pivot
      (
        max(answ) 
        for ques in ('+ @colspivot +')
      ) p'

exec(@query)

SQL FiddlewithDemoを参照してください

于 2012-10-01T15:50:14.153 に答える