nsis - ドロップダウン メニューのアイテム間の余分な改行文字

Question

nsis インストーラーを使用してインストーラーを作成しています。そのインストーラーでは、通貨を選択するためのドロップダウン メニューを配置する必要があります。

使用しているテキスト ファイルが正しく挿入されていません。通貨を区切るために使用している改行文字が実際にインストーラーで文字を取得していますが、ライセンス ページでは、テキスト ファイルに同じ拡張子を使用しています。そこに置いていますが、あちらでは正常に動作しています。

これらの余分な文字を除外するにはどうすればよいですか?

Answer 1

サンプルファイルがなければ、実際の問題が何であるかを推測する必要がありました。うまくいけば、改行だけです。

Page custom mycustompage

!include nsDialogs.nsh
!include TextFunc.nsh

Function mycustompage
nsDialogs::Create 1018
Pop $0

; I don't have a list of things so I generate one on the fly for this example:
!tempfile MYLIST
!appendfile "${MYLIST}" "Foo$\r"
!appendfile "${MYLIST}" "Bar$\r$\n"
!appendfile "${MYLIST}" "Baz$\n"
File "/oname=$pluginsdir\thelist.txt" "${MYLIST}" ; include list in installer
!delfile "${MYLIST}"

${NSD_CreateDropList} 10u 10u 50% 100% ""
Pop $0

FileOpen $1 "$pluginsdir\thelist.txt" r
loop:
    FileRead $1 $2
    IfErrors endloop
    ${TrimNewLines} $2 $2
    StrCmp $2 "" loop ; skip empty line
    ${NSD_CB_AddString} $0 $2
    goto loop
endloop:

nsDialogs::Show
FunctionEnd