2

背景: と で記述された内部イントラネット システムがあります- サーバーにはこのような php の気の利いたソリューションをいくつか見ましたが、実際にはこれらを使用することはできません)。 imap メールボックスにある未読メールの数。彼らの imap メールボックスは、postfix と dovecot imap を実行している Linux ボックスで内部的にホストされています。

私の質問: .net (vb または c#) で Dovecot Imap を介して Postfix メール システムに接続し、未読アイテムの数を確認するにはどうすればよいですか?

私がすでに試したこと: Limilabs メール dllと以下 を使用しました。

Imports System.Net.Security
Imports System
Imports Limilabs.Mail
Imports Limilabs.Client.IMAP
Imports Limilabs.Client

Function RetrieveUnread(_server, _user, _password)
    Using imap As New Limilabs.Client.IMAP.Imap
        '#### Handler needed because of self signed certificates
        RetrieveUnread = vbNull
        AddHandler imap.ServerCertificateValidate, AddressOf ValidateCertificate
        imap.ConnectSSL(_server)
        Try
            imap.Login(_user, _password)
        Catch ex As Exception
            RetrieveUnread = "Failed to login"
        End Try
        If CStr(RetrieveUnread) <> "Failed to login" Then
            imap.SelectInbox()
            Dim uids As List(Of Long) = imap.Search(Flag.Unseen)        'Find all unseen messages.
            'Console.WriteLine("Number of unseen messages is: " & CStr(uids.Count))
            RetrieveUnread = CStr(uids.Count)
        End If
        imap.Close()
    End Using
End Function

Private Sub ValidateCertificate(ByVal sender As Object, ByVal e As ServerCertificateValidateEventArgs)
    Const ignoredErrors As SslPolicyErrors = SslPolicyErrors.RemoteCertificateChainErrors Or SslPolicyErrors.RemoteCertificateNameMismatch        ' name mismatch
    Dim nameOnCertificate As String = e.Certificate.Subject
    If (e.SslPolicyErrors And Not ignoredErrors) = SslPolicyErrors.None Then
        e.IsValid = True
        Return
    End If
    e.IsValid = False
End Sub

ただし、これは機能しますが、この方法はサードパーティに依存する可能性があります。ライセンスが適切でない場合、または最新の状態ではない場合、DLL は失敗します。これがネイティブの .net コードで実行できるかどうかに興味があります。

4

1 に答える 1

2

サードパーティの dll は必要ありません。簡単TcpClientにできます。

適切な IMAP コマンドをサーバーに送信するだけで、結果を正規表現で解析できます。

LINQPad 対応の例:

Sub Main()
    Dim client = New System.Net.Sockets.TcpClient("hostname", 143)
    Using s = client.GetStream(), 
        reader = New StreamReader(s),
        writer = New StreamWriter(s)

            Dim send As Action(Of String) = Sub(command) 
                writer.WriteLine(command)
                writer.Flush()
            End Sub

            Dim recieve As Func(Of String, String) = Function(tag) 
                Dim response As String
                Dim str As String = ""
                response = reader.ReadLine()
                While response IsNot Nothing
                    str += response
                    If response.StartsWith(tag, StringComparison.Ordinal) Then
                        Exit While
                    End If
                    response = reader.ReadLine()
                End While
                Return str
            End Function

            send("a login username password"): recieve("a")
            send("b select inbox"): recieve("b")

            send("b2 SEARCH UNSEEN")
            Dim b2response = recieve("b2")
            Dim items = Regex.Match(b2response, "SEARCH (.*) OK").Groups(1).Value.Split(" "c)
            Console.WriteLine("Unread items: " + items.Count().ToString())

            send("c logout"): recieve("c")
    End Using
End Sub

void Main()
{
    var client = new System.Net.Sockets.TcpClient("hostname", 143);
    using (var s = client.GetStream())
    using (var reader = new StreamReader(s))
    using (var writer = new StreamWriter(s))
    {
        Action<string> send = (command) => 
        {
            writer.WriteLine(command);
            writer.Flush();
        };

        Func<String, String> recieve = (tag) =>
        {
            string response;
            string str="";
            while ((response = reader.ReadLine()) != null ) 
            {
                str+=response;
                if (response.StartsWith(tag, StringComparison.Ordinal))
                    break;
            }
            return str;
        };

        send("a login username password"); recieve("a");
        send("b select inbox"); recieve("b");

        send("b2 SEARCH UNSEEN");
        var b2response = recieve("b2");
        var items = Regex.Match(b2response, @"SEARCH (.*) OK").Groups[1].Value.Split(' ');
        Console.WriteLine("Unread items: " + items.Count().ToString());

        send("c logout"); recieve("c");
    }
}

SSL を使用する場合は、最初にストリームをラップsしてSslStreamand を呼び出す必要がありますAuthenticateAsClient(おそらくポート 993 を使用します)。

于 2012-10-04T10:48:27.563 に答える