perl - Perlでファイルに書き込む

Question

検討：

#!/usr/local/bin/perl
$files = "C:\\Users\\A\\workspace\\CCoverage\\backup.txt";
unlink ($files);
open (OUTFILE, '>>$files');
print OUTFILE "Something\n";
close (OUTFILE);

上記は私がPerlで書いた単純なサブルーチンですが、機能していないようです。どうすればそれを機能させることができますか？

Answer 1

変数は、二重引用符を使用して文字列でのみ補間されます"。一重引用符を使用する場合'、$はドルとして解釈されます。

">>$files"の代わりに試してください'>>$files'

常に使用する

use strict;
use warnings;

さらにいくつかの警告を受け取るのに役立ちます。

いずれにせよ、変数も宣言します

my $files = "...";

open：の戻り値も確認する必要があります。

open OUTFILE, ">>$files"
  or die "Error opening $files: $!";

編集：コメントで示唆されているように、3つの引数が開いているバージョンと他のいくつかの可能な改善

#!/usr/bin/perl

use strict;
use warnings;

# warn user (from perspective of caller)
use Carp;

# use nice English (or awk) names for ugly punctuation variables
use English qw(-no_match_vars);

# declare variables
my $files = 'example.txt';

# check if the file exists
if (-f $files) {
    unlink $files
        or croak "Cannot delete $files: $!";
}

# use a variable for the file handle
my $OUTFILE;

# use the three arguments version of open
# and check for errors
open $OUTFILE, '>>', $files
    or croak "Cannot open $files: $OS_ERROR";

# you can check for errors (e.g., if after opening the disk gets full)
print { $OUTFILE } "Something\n"
    or croak "Cannot write to $files: $OS_ERROR";

# check for errors
close $OUTFILE
    or croak "Cannot close $files: $OS_ERROR";