1

VBScript私は、要求を送信し、返される応答HTTP POSTを読み取るこの単純なものを持っています。HTML

Function httpPOST(url, body, username, password )  
  Set Http = CreateObject("Msxml2.ServerXMLHTTP")   
  Http.Open "POST", url, False, username, password  
  Http.setRequestHeader _  
              "Content-Type", _  
              "application/x-www-form-urlencoded"  
  Http.send body 
  pagestatus = Http.status
  if pagestatus<> "200" then
    httpPOST="Error:"& pagestatus
  else
    'httpPOST = Http.ResponseBody
    'httpPOST = Http.responseText
    Set objXMLDoc = CreateObject("MSXML.DOMDocument")
    objXMLDoc.async = False
    objXMLDoc.validateOnParse = False
    objXMLDoc.load(Http.ResponseBody)
    Set objNode = objXMLDoc.selectSingleNode("/html/body/center/img")
    httpPost = objNode.getAttribute("alt") 
  end if
End Function

HTML応答形式は次のとおりです。

<html>
    <head>
        <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1" />
        <title>---</title>
    </head>
    <body>
        <center>
            <img alt="You are now connected" src="pages/GEN/connected_gen.png">
        </center>
    </body>
</html>

このスクリプトの問題は、常に返されることですError: Object required: 'objNode'

私は非常に多くのバリエーションのパーサーを試しましたが、オブジェクトXMLに関連する同じエラーが発生するたびに、最終的にあきらめました。XML

4

1 に答える 1

2

最初の問題はここで対処されます：.loadexpects'XMLファイルの場所を指定するURLを含む文字列'; したがって、.loadXmlを使用して、解析可能なHttp.ResponseBody データが含まれているかどうかを確認しMSXML?.DOMDocumentます（2番目の問題）。

アップデート：

「機能する」もの（およびその理由）：

  Dim sHTML : sHTML = readAllFromFile("..\data\02.html")
  WScript.Echo sHTML
  Dim oXDoc : Set oXDoc = CreateObject("MSXML2.DOMDocument")
  oXDoc.async = False
  oXDoc.validateOnParse = False
  oXDoc.setProperty "SelectionLanguage", "XPath"
  If oXDoc.loadXML(sHTML) Then
     Dim ndImg : Set ndImg = oXDoc.selectSingleNode("/html/body/center/img")
     Dim httpPost : httpPost = ndImg.getAttribute("alt")
     WScript.Echo "ok", httpPost
  Else
     WScript.Echo "Error: " & trimWS(oXDoc.parseError.reason)
  End If

出力：

<html>
    <head>
        <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1" />
        <title>---</title>
    </head>
    <body>
        <center>
            <img alt="You are now connected" src="pages/GEN/connected_gen.png"/>
        </center>
    </body>
</html>

ok You are now connected

MSXML2.DOMDocument.loadXMLは、「XMLが有効」である場合、HTMLコードを（および解析して）実行します。imgタグが閉じられていないため、HTMLは閉じられていません-元のコードに対して表示されたエラーメッセージ：

Error: End tag 'center' does not match the start tag 'img'.

さらに先に進む方法は、HTMLを変更できるかどうかによって異なります。

更新II：

.loadXMLにフィードする前に.ResponseBodyに厄介なことをすることもできますが、HTMLツールを使用してHTMLを解析してみませんか。

  Dim sHTML : sHTML = readAllFromFile("..\data\01.html")
  WScript.Echo sHTML
  Dim oHF : Set oHF = CreateObject("HTMLFILE")
  oHF.write sHTML
  Dim httpPost : httpPost = oHF.documentElement.childNodes(1).childNodes(0).childNodes(0).alt
  WScript.Echo "ok", httpPost

出力：

<html>
    <head>
        <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1" />
        <title>---</title>
    </head>
    <body>
        <center>
            <img alt="You are now connected" src="pages/GEN/connected_gen.png">
        </center>
    </body>
</html>

ok You are now connected

出力が示すように、HTMLFILEは'not-xml-closed'imgを受け入れます。もちろん、本当に欲しいものを手に入れる方法は消毒する必要があります。

于 2012-10-05T15:59:07.597 に答える