perl - 配列内のすべての文字列が2番目の配列にあるかどうかを確認します

Question

2つのアレイがあるとしましょう

my @one = ("one","two","three","four","five");
my @two = ("three","five");

2番目の配列のすべての要素が最初の配列にあるかどうかを確認するにはどうすればよいですか？

Answer 1

my %one = map { $_ => 1 } @one;
if (grep($one{$_}, @two) == @two) {
   ...
}

Answer 2

解決するためのさらに別の方法。

my %hash;
undef @hash{@two};  # add @two to keys %hash 
delete @hash{@one}; # remove @one from keys %hash 
print !%hash;       # is there anything left? 

このperlmonksノードからアイデアを盗んだ

Answer 3

use strict;

my @one = ("one","two","three","four","five");
my @two = ("three","five");

my %seen_in_one = map {$_ => 1} @one;

if (my @missing = grep {!$seen_in_one{$_}} @two) {
    print "The following elements are missing: @missing";
} else {
    print "All were found";
}

Answer 4

別の方法、池上より良いかどうかはわかりません。それでもTIMTOWTDI

#!/usr/bin/env perl

use strict;
use warnings;

use List::Util qw/first/;
use List::MoreUtils qw/all/;

my @one = ("one","two","three","four","five");
my @two = ("three","five");

if ( all { my $find = $_; first { $find eq $_ } @one } @two ) {
  print "All \@two found in \@one\n";
}

Answer 5

5.10以降、スマートマッチ演算子がそれを実行します。

my $verdict = !grep { not $_ ~~ @one } @two;

またはList::MoreUtils::all：

my $verdict = all { $_ ~~ @one } @two;