4

私はxsltが初めてです。次のようなxmlファイルがあります

<EmpCollection>
<Emp>
<Name>Sai</Name>
<Sal>7000</Sal>
</Emp>
<Emp>
<Name>Nari</Name>
<Sal>7400</Sal>
</Emp>
<Emp>
<Name>Hari</Name>
<Sal>9000</Sal>
</Emp>
<Emp>
<Name>Suri</Name>
<Sal>8900</Sal>
</Emp>
</EmpCollection>

sum() 関数を使用せずに給与の合計を追加します。明確な方法でxsltを学びたい:-)

4

2 に答える 2

1

I.おそらく最も単純な解決策の1つ：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="Sal">
  <xsl:param name="pSum" select="0"/>
     <xsl:apply-templates select="following::Sal[1]">
       <xsl:with-param name="pSum" select="$pSum + ."/>
     </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="Sal[not(following::Sal)]">
  <xsl:param name="pSum" select="0"/>
  <xsl:value-of select="$pSum + ."/>
 </xsl:template>

 <xsl:template match="/">
  <xsl:apply-templates select="descendant::Sal[1]"/>
 </xsl:template>
</xsl:stylesheet>

この変換が提供されたXMLドキュメントに適用される場合：

<EmpCollection>
    <Emp>
        <Name>Sai</Name>
        <Sal>7000</Sal>
    </Emp>
    <Emp>
        <Name>Nari</Name>
        <Sal>7400</Sal>
    </Emp>
    <Emp>
        <Name>Hari</Name>
        <Sal>9000</Sal>
    </Emp>
    <Emp>
        <Name>Suri</Name>
        <Sal>8900</Sal>
    </Emp>
</EmpCollection>

必要な正しい結果が生成されます。

32300

II。より一般的な解決策は、次のようなFXSL2.x関数を使用することですf:foldl()。

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="http://fxsl.sf.net/" exclude-result-prefixes="f">
   <xsl:import href="../f/func-foldl.xsl"/>
   <xsl:import href="../f/func-Operators.xsl"/>

   <xsl:output  encoding="UTF-8" omit-xml-declaration="yes"/>

    <xsl:template match="/">
      <xsl:value-of select="f:foldl(f:add(), 0, /*/*/Sal)"/>
    </xsl:template>
</xsl:stylesheet>

このXSLT2.0変換を同じXM​​Lドキュメント（上記）に適用すると、同じ正しい必要な結果が生成されます。

32300

任意の2つの引数関数を引数として渡してf:foldl()、さまざまな問題の解を生成できます。

たとえば、f:mult()代わりに渡すf:add()（および「ゼロ」引数をに変更する1）と、給与の積が生成されます。

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="http://fxsl.sf.net/" exclude-result-prefixes="f">
   <xsl:import href="../f/func-foldl.xsl"/>
   <xsl:import href="../f/func-Operators.xsl"/>

   <xsl:output  encoding="UTF-8" omit-xml-declaration="yes"/>

    <xsl:template match="/">
      <xsl:value-of select="f:foldl(f:mult(), 1, /*/*/Sal)"/>
    </xsl:template>
</xsl:stylesheet>

この変換を同じXM​​Lドキュメントに適用した結果は、すべてのSal要素の積になります。

4.14918E15

III。XSLT 3.0（XPath 3.0）では、前のソリューションとまったく同じ方法で標準fold-left()または fold-right()関数を使用できます。

于 2012-10-11T12:00:52.163 に答える
0

おそらくもっとエレガントな方法があります (そして私は推測sum()します :) が、次のように兄弟を足し算で「折り畳む」ことによって機能します。終了条件は最後の兄弟 (つまり、後続のノードがない) です。

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="1.0">
    <xsl:output method="xml" omit-xml-declaration="yes"/>

    <xsl:template match="/EmpCollection">
        <result>Result Is : <xsl:apply-templates select="Emp[1]"/>
        </result>
    </xsl:template>

    <xsl:template match="Emp[following-sibling::Emp]">
        <xsl:variable name="salThis">
            <xsl:value-of select="Sal"/>
        </xsl:variable>
        <xsl:variable name="salOthers">
            <xsl:apply-templates select="following-sibling::Emp[position()=1]"/>
        </xsl:variable>
        <xsl:value-of select="$salThis + $salOthers"/>
    </xsl:template>

    <!--Termination - the last employee just returns its salary value-->
    <xsl:template match="Emp[not(following-sibling::Emp)]">
        <xsl:value-of select="Sal"/>
    </xsl:template>
</xsl:stylesheet>

結果を与える：

<result>Result Is : 32300</result>

編集

あなたの質問をもう一度読んだ後、これはコードゴルフの質問ではないと思いますか? 以下は、ハードコーディングされた要素名を使用してこれを行うより簡単な方法です。これは、指定された従業員の給与を合計するようプロセッサに指示します。

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="1.0">
    <xsl:output method="xml" omit-xml-declaration="yes"/>

    <xsl:template match="/EmpCollection">
        <result>
            Result Is : <xsl:value-of select="Emp[Name='Sai']/Sal + Emp[Name='Nari']/Sal + Emp[Name='Hari']/Sal + Emp[Name='Suri']/Sal"/>
        </result>
    </xsl:template>

</xsl:stylesheet>

sum()これにより、何が行われているかを簡単に理解できるようになります。

<xsl:template match="/EmpCollection">
    <result>
        Result Is : <xsl:value-of select="sum(Emp/Sal)"/>
    </result>
</xsl:template>

編集

カウントは単純です：

<xsl:template match="/EmpCollection">
    <result>
        <xsl:text>Count Is : </xsl:text>
        <xsl:value-of select="count(Emp)"/>
    </result>
</xsl:template>

なしでこれを行うcount()のはそれほど簡単ではありません。xsl:variables は一度割り当てられると変更できないことに注意してください(不変)。したがって、以下はまったく機能しません。

<xsl:template match="/EmpCollection">
    <xsl:variable name="count" select="0" />
    <xsl:for-each select="Emp">
        <!--NB : You can't do this. Variables are immutable - XSLT is functional -->
        <xsl:variable name="count" select="$count + 1"></xsl:variable>
    </xsl:for-each>
    <result>
        Result Is : <xsl:value-of select="$count"/>
    </result>
</xsl:template>

したがって、すべてのノードを「ループ」してから、 を使用position()して、これがシーケンスの最後のノードであるかどうかを判断できます。( を使用しましfor-eachたが、実際には use を使用する方がよいことに注意してくださいapply-template)

<xsl:template match="/EmpCollection">
    <result>
        <xsl:text>Count Is : </xsl:text>
        <xsl:for-each select="Emp">
            <xsl:if test="position() = last()">
                <xsl:number value="position()" format="1" />
            </xsl:if>
        </xsl:for-each>
    </result>
</xsl:template>

:(

于 2012-10-11T08:20:16.900 に答える