.net - .NET4.5を使用したNSISインストーラー

Question

NSISが.NET4.5インストーラーを検出して条件付きで実行するためのコードスニペットを探しています

この回答（.NET 4.0を使用するNSISインストーラー）は、レジストリキー（値ではなく）の存在のみをチェックしても4.0と4.5を区別できないため、単純すぎます。

Answer 1

正確なバージョン番号を確認するべきではありません。これは将来変更されます（4.0> 4.5の場合のように）。代わりに、導入ガイドのコードを使用してください。

それに加えて、.Net4.5からの再起動を処理するようにしてください。

Function CheckAndInstallDotNet
    ; Magic numbers from http://msdn.microsoft.com/en-us/library/ee942965.aspx
    ClearErrors
    ReadRegDWORD $0 HKLM "SOFTWARE\Microsoft\NET Framework Setup\NDP\v4\Full" "Release"

    IfErrors NotDetected

    ${If} $0 >= 378389

        DetailPrint "Microsoft .NET Framework 4.5 is installed ($0)"
    ${Else}
    NotDetected:
        DetailPrint "Installing Microsoft .NET Framework 4.5"
        SetDetailsPrint listonly
        ExecWait '"$INSTDIR\Tools\dotNetFx45_Full_setup.exe" /passive /norestart' $0
        ${If} $0 == 3010 
        ${OrIf} $0 == 1641
            DetailPrint "Microsoft .NET Framework 4.5 installer requested reboot"
            SetRebootFlag true
        ${EndIf}
        SetDetailsPrint lastused
        DetailPrint "Microsoft .NET Framework 4.5 installer returned $0"
    ${EndIf}

FunctionEnd