2 
<choices>
   <sic  />
   <corr />
   <reg  />
   <orig />
</choices>

<choice>
   <corr>Red</corr>
   <sic>Blue</sic>
<choice>

<choice>内の任意の要素の名前と名前が一致する最初の要素を選択したいと考えています<choices>。

name(node-set) が最初のノードの名前だけでなく、名前のリストを返した場合、次を使用できます

select="choice/*[name() = name(choices/*)][1]"

しかし、そうではありません (少なくとも 1.0 ではそうではありません)。代わりに、名前を文字列に結合して、contains() を使用します。

<xsl:variable name="choices.str">
    <xsl:for-each select="choices/*">
        <xsl:text> </xsl:text><xsl:value-of select="concat(name(),' ')"/>
    </xsl:for-each>
</xsl:variable>
<xsl:apply-templates select="choice/*[contains($choices.str,name())][1]"/>

そして私が欲しいものを手に入れます：

Red、の値<corr>

もっと簡単な方法はありますか？

4

2 に答える 2

2

I. この XPath 2.0 ワンライナーを使用します。

/*/choice/*[name() = /*/choices/*/name()][1]

この XPath 式が次の XML ドキュメント(提供されたものですが、整形式の XML ドキュメントになるように修正されています) に対して評価される場合:

<t>
    <choices>
        <sic  />
        <corr />
        <reg  />
        <orig />
    </choices>
    <choice>
        <corr>Red</corr>
        <sic>Blue</sic>
    </choice>
</t>

正しい要素が選択されています:

<corr>Red</corr>

Ⅱ．XSLT 1.0 (キーなし!):

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vNames">
  <xsl:for-each select="/*/choices/*">
   <xsl:value-of select="concat(' ', name(), ' ')"/>
  </xsl:for-each>
 </xsl:variable>

 <xsl:template match="/">
  <xsl:copy-of select=
  "/*/choice/*
         [contains($vNames, concat(' ', name(), ' '))]
           [1]"/>
 </xsl:template>
</xsl:stylesheet>

この変換が同じ XML ドキュメント (上記) に適用されると、再び正しい要素が選択されます (出力にコピーされます)。

<corr>Red</corr>

III. キーの使用:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

  <xsl:key name="kChoiceByName" match="choice/*"
   use="boolean(/*/choices/*[name()=name(current())])"/>

 <xsl:template match="/">
  <xsl:copy-of select="/*/choice/*[key('kChoiceByName', true())][1]"/>
 </xsl:template>
</xsl:stylesheet>

この変換が同じ XML ドキュメント (上記) に対して適用されると、同じ正しい結果が生成されます。

<corr>Red</corr>

これがどのように「機能する」かを理解しようとすることを読者にお勧めします:)

于 2012-10-11T23:57:28.177 に答える
1

次のように key() 関数を使用できます...

この入力ドキュメントが...

<t>
<choices>
   <sic  />
   <corr />
   <reg  />
   <orig />
</choices>
<choice>
   <corr>Red</corr>
   <sic>Blue</sic>
  </choice>
</t>

...この XSLT 1.0 スタイルシートへの入力として提供されます...

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
<xsl:key name="kChoices" match="choices/*" use="name()" />  

<xsl:template match="/">
  <xsl:variable name="first-choice" select="(*/choice/*[key('kChoices',name())])[1]" />
  <xsl:value-of select="$first-choice" />
  <xsl:text>, the value of &lt;</xsl:text>
  <xsl:value-of select="name( $first-choice)" />
  <xsl:text>&gt;</xsl:text>
</xsl:template>

</xsl:stylesheet>

...この出力テキストが生成されます...

Red, the value of <corr>

XSLT 2.0 はさておき

XSLT 2.0 では、$first-choice 変数の計算に次の代替手段を使用できます...

オプション1：

(*/choice/*[for $c in . return ../../choices/*[name()=name($c)]])[1]

オプション 2:

(*/choice/*[some $c in ../../choices/* satisfies name($c)=name()])[1]
于 2012-10-11T23:52:54.050 に答える