excel - 複数の列でIfをカウントする方法は？

Question

x = 0
For Each cell in Sheets("01").Range("A:A").Cells
If cell.Value = "aaa" And cell.Offset(0, 1).Value = "bbb" Then
x = x+1
End If
Next cell
MsgBox x

もっと短い方法はありますか、pls？

Answer 1

あなたはこのような式でこれを行うことができます

（Excel 2007以降）

=COUNTIFS(A:A,"aaa",B:B,"bbb")

（Excel 2003以前）

=SUMPRODUCT(--(A:A="aaa")*--(B:B="bbb"))

または、VBAで行う必要がある場合は、Evaluate

MsgBox Evaluate("=COUNTIFS(A:A,""aaa"",B:B,""bbb"")")

MsgBox Evaluate("=SUMPRODUCT(--(A:A=""aaa"")*--(B:B=""bbb""))")

---

あなたのコメントに基づいて編集

rDatとrSecがRange'sでありct、シートCodeNameがこのようになっている場合

Dim rDat As Range
Dim rSec As Range
Set rDat = ct.[A:A]
Set rSec = ct.[B:B]
ct.Range("C6").Value = Evaluate("=COUNTIFS(" & rDat.Address(, , , True) & " ,""a""," & rSec.Address(, , , True) & ",""1"")")

---

ctシートの場合は、Nameこれを使用してください

Dim ws As Worksheet
Dim rDat As Range
Dim rSec As Range
Set ws = ActiveWorkbook.Worksheets("ct")
Set rDat = ws.[A:A]
Set rSec = ws.[B:B]
ws.Range("C6").Value = Evaluate("=COUNTIFS(" & rDat.Address(, , , True) & " ,""a""," & rSec.Address(, , , True) & ",""1"")")

rDatおよびが文字列の場合rSecは、これを使用します

Dim ws As Worksheet
Dim rDat As String
Dim rSec As String
Set ws = ActiveWorkbook.Worksheets("ct")
rDat = "ct!A:A"
rSec = "ct!B:B"
ws.Range("C6").Value = Evaluate("=COUNTIFS(" & rDat & " ,""a""," & rSec & ",""1"")")

---

別のオプション（のrDat、rSec範囲として）

ct.Range("C6").Value = Application.WorksheetFunction.CountIfs(rDat, "a", rSec, "1")