5

ピボットテーブルを作成しようとしていますが、取得していInvalid Procedure Call or Argumentます。

ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:="rng", Version:=xlPivotTableVersion14).CreatePivotTable TableDestination:="rngB", TableName:="pvtReportA_B", DefaultVersion:=xlPivotTableVersion14
  • rng（ソース）は、約20列と数千行で構成される範囲です。
  • rngB（宛先）は、別のワークシートの単一のセルです

誰かが私がどこで間違っているのかアドバイスできますか？

編集：

私のせいで、私はソースとしてではrngDataなく、使用するべきでした。rng

    Set rng = wsA.Range("C14")
    Set rngData = Range(rng, rng.End(xlToRight))
    Set rngData = Range(rng, rng.End(xlDown))
    Set rngB = wsB.Range("C8")

    ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=rngData, Version:=xlPivotTableVersion14).CreatePivotTable TableDestination:=rngB, TableName:="pvtReportA_B", DefaultVersion:=xlPivotTableVersion14

これにより、ピボットテーブルフレームが正常に表示されます。

4

2 に答える 2

4

この例では、間違った範囲オブジェクトを使用したため、Excel が適合をスローしました。

Set rng = wsA.Range("C14")
Set rngData = Range(rng, rng.End(xlToRight))
Set rngData = Range(rng, rng.End(xlDown))
Set rngB = wsB.Range("C8")

ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=rngData, Version:=xlPivotTableVersion14).CreatePivotTable TableDestination:=rngB, TableName:="pvtReportA_B", DefaultVersion:=xlPivotTableVersion14
于 2012-10-14T13:59:24.090 に答える
3

VBA コードを使用してExcel 2010でピボットを作成するには、次のテンプレートを使用して適応させることができます。

Sub newPVT()
    Dim PTCache As PivotCache
    Dim PT As PivotTable

    'Create the Cache
    Set PTCache = ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, _
        SourceData:=Range("Dynamic_Field_Summary"))

    'Select the destination sheet
    Sheets("Field Summary").Select

    'Create the Pivot table
    Set PT = ActiveSheet.PivotTables.Add(PivotCache:=PTCache, _
        TableDestination:=Range("P1"), TableName:="Pivot1")

    ActiveWorkbook.ShowPivotTableFieldList = True

    'Adding fields
    With PT
        With .PivotFields("Enterprise")
            .Orientation = xlColumnField
            .Position = 1
        End With

        With .PivotFields("Field")
            .Orientation = xlRowField
            .Position = 1
        End With

        With .PivotFields("Planted Acres")
            .Orientation = xlDataField
            .Position = 1
            .Caption = " Planted Acres"
            .Function = xlSum
        End With

        With .PivotFields("Harvested Acres")
            .Orientation = xlDataField
            .Position = 2
            .Caption = " Harvested Acres"
            .Function = xlSum
        End With

        With .PivotFields("lbs")
            .Orientation = xlDataField
            .Position = 3
            .Caption = " lbs"
            .Function = xlSum
        End With

        'Adjusting some settings
        .RowGrand = False
        .DisplayFieldCaptions = False
        .HasAutoFormat = False

        'Improving the layout
        .TableStyle2 = "PivotStyleMedium9"
        .ShowTableStyleRowStripes = True
        .ShowTableStyleColumnStripes = True

    End With

    With ActiveSheet
        'Adjusting columns width
        .Columns("P:V").ColumnWidth = 16
        .Range("Q2:V2").HorizontalAlignment = xlCenter
    End With

    ActiveWorkbook.ShowPivotTableFieldList = False
End Sub

ここで見つけました。

このページでは、コードのすべての部分の意味を詳しく説明することもできます。たとえば、ここで説明されています。これは、Excel 2007 やその他のバージョンの vba マクロの作成を開始するのにも適したコードだと思います。

于 2013-11-17T11:44:13.203 に答える