2

誰かが配列で以下を取得するのを手伝ってくれますか..私は一般化されたxslを生成する必要があります..入力XML：

<Login>
    <Groups>
        <Group>
            <Name>john</Name>
            <Password/>
        </Group>
        <Group>
            <Name>john</Name>
            <Password/>
        </Group>
    </Groups>
</Login>

出力：

<json:object xmlns:json="http://www.ibm.com/xmlns/prod/2009/jsonx" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
    <json:object name="Login">
        <json:object name="Groups">
            <json:array name="Group">
                <json:object>
                    <json:string name="Name">john</json:string>
                    <json:string name="Password"/>
                </json:object>
                <json:object>
                    <json:string name="Name">john</json:string>
                    <json:string name="Password"/>
                </json:object>
            </json:array>
        </json:object>
    </json:object>
</json:object>
4

3 に答える 3

2

より一般化されたソリューション。XSLT 2.0 が必要

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:json="http://www.ibm.com/xmlns/prod/2009/jsonx" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />

    <xsl:template match="/">
        <xsl:element name="json:object">
            <xsl:apply-templates />    
        </xsl:element>
    </xsl:template>

    <xsl:template match="*[*]">
        <xsl:param name="nodeName" select="name()" />
        <xsl:variable name="firstNodeName" select="name(*[1])" />

        <xsl:element name="json:object">
            <xsl:if test="$nodeName">
                <xsl:attribute name="name" select="$nodeName" />
            </xsl:if>
            <xsl:choose>
                <xsl:when test="(count(*) > 1) and (every $x in */name() satisfies $x=$firstNodeName)">
                    <xsl:element name="json:array">
                        <xsl:attribute name="name" select="$firstNodeName" />

                        <xsl:apply-templates >
                            <xsl:with-param name="nodeName" select="''" />
                        </xsl:apply-templates>
                    </xsl:element>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:apply-templates />
                </xsl:otherwise>
            </xsl:choose>
        </xsl:element>
    </xsl:template>

    <xsl:template match="*[not(*)]">
        <xsl:element name="json:string">
            <xsl:attribute name="name">
                <xsl:value-of select="name()" />
            </xsl:attribute>
            <xsl:value-of select="text()" />
        </xsl:element>
    </xsl:template> 
</xsl:stylesheet>

提供されたサンプル XML に適用すると、次の出力が生成されます。

<?xml version="1.0" encoding="UTF-8"?>
<json:object xmlns:json="http://www.ibm.com/xmlns/prod/2009/jsonx">
    <json:object name="Login">
        <json:object name="Groups">
            <json:array name="Group">
                <json:object>
                    <json:string name="Name">john</json:string>
                    <json:string name="Password"></json:string>
                </json:object>
                <json:object>
                    <json:string name="Name">john</json:string>
                    <json:string name="Password"></json:string>
                </json:object>
            </json:array>
        </json:object>
    </json:object>
</json:object>

上記のソリューションは、次のサイトでテストされました: http://xslttest.appspot.com/

編集：

every $x in */name() satisfies $x=$firstNodeName*/name()シーケンス内のすべての要素が $firstNodeName と等しいかどうかをチェックする XPATH 2.0 構造です。したがって、この条件全体は実際には、ノードに同じ名前の子が複数あるかどうかをチェックすることを意味します。これは、大文字とjson:array小文字を区別しているかどうかをチェックするための条件です。

于 2012-10-15T09:28:10.090 に答える