0

'ofd はファイルを開くダイアログです

Dim img As Bitmap
Dim iscmyk As Boolean
Dim i As String
Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click


    ofd.Filter = "Jpg Image(*.jpg)|*.jpg"
    If ofd.ShowDialog = Windows.Forms.DialogResult.OK Then
        img = Bitmap.FromFile(ofd.FileName)
        iscmyk = ((DirectCast(img.Flags, Imaging.ImageFlags) And Imaging.ImageFlags.ColorSpaceCmyk) = Imaging.ImageFlags.ColorSpaceCmyk)
    End If
    img = New Bitmap(img, New Size(120, 190))
    MsgBox("cmyk = " & iscmyk)
    PictureBox1.Image = img
End Sub

画像がcmykかrgbかを確認する必要があります.cmykの場合、iscmykはtrueを返し、cmykでない場合、iscmykはWindows 7 PCでfalseを返します。各画像とすべての画像に対してfalseを返しますが、XPでは完璧な答えを返します

なぜ私の他のwin7 PCで動作しないのですか???

4

1 に答える 1

2
  • まず、返信が遅くなってすみません...
  • 第二に、実際には、OSのバージョンが異なると結果が異なる理由がわかりません。

とにかく、ここに低レベルの（そして醜い）回避策があります。JPEG画像用に設計されています：

Public Shared Function GetJpegBpp(FileName As String) As Integer
    Dim len As Integer
    Dim fp As FileStream = Nothing
    Dim marker(1) As Byte
    Dim data(15) As Byte
    Dim components As Byte = 0

    GetJpegBpp = -2
    Try
        fp = New FileStream(FileName, FileMode.Open, FileAccess.Read)
        GetJpegBpp = -1
        If fp.Read(marker, 0, 2) < 2 OrElse marker(0) <> &HFF OrElse marker(1) <> &HD8 Then Exit Function
        Do
            If fp.Read(marker, 0, 2) < 2 OrElse marker(0) <> &HFF OrElse (marker(1) > 1 And marker(1) < &HC0) Then Exit Function
            If (marker(1) < &HD0 Or marker(1) > &HD9) AndAlso marker(1) > 1 Then
                If fp.Read(data, 0, 2) < 2 Then Exit Function
                len = (CInt(data(0)) << 8) Or data(1)
                len -= 2
                If len < 0 Then Exit Function
                If (marker(1) >= &HC0) And (marker(1) <= &HC3) Then
                    If len < 9 OrElse fp.Read(data, 0, 6) < 6 Then Exit Function
                    components = data(5)
                    If components = 0 OrElse components = 2 OrElse components > 4 OrElse (components * 3 + 6) <> len Then Exit Function
                    len -= 6
                ElseIf marker(1) = &HDA Then
                    If len < (4 + 2 * components) Or (fp.ReadByte() <> components) Then Exit Function
                    len -= 1
                End If
                fp.Position += len
            End If
        Loop Until marker(1) = &HDA Or marker(1) = &HD9
        If components = 0 OrElse marker(1) = &HD9 OrElse (fp.Length - fp.Position) < 3 Then Exit Function
    Catch
        Exit Function
    Finally
        If Not fp Is Nothing Then fp.Close()
    End Try
    GetJpegBpp = components * 8
End Function

この行を置き換える必要があります

iscmyk = ((DirectCast(img.Flags, Imaging.ImageFlags) And Imaging.ImageFlags.ColorSpaceCmyk) = Imaging.ImageFlags.ColorSpaceCmyk)

これとともに：

iscmyk = (GetJpegBpp(ofd.FileName) = 32)

最後に、このコードをCMYK JPEG画像でテストしていませんが、動作するはずです...

于 2012-10-30T05:45:34.070 に答える