5

Promotion次のような行とデータを含むテーブルがあるとします。

PromotionId    Codes
1              a,b
2              c
3              d,e,f

次のように返すクエリを作成するにはどうすればよいですか。

PromotionId    Codes
1              a
1              b
2              c
3              d
3              e
3              f

基本的に、コードを複数の行に文字列分割したいと思います。

4

3 に答える 3

9

Split次のように、テーブル値関数を使用できます。

CREATE FUNCTION [dbo].[Split]
(
    @ItemList NVARCHAR(MAX), 
    @delimiter CHAR(1)
)
RETURNS @IDTable TABLE (Item VARCHAR(50))  
AS      

BEGIN    
    DECLARE @tempItemList NVARCHAR(MAX)
    SET @tempItemList = @ItemList

    DECLARE @i INT    
    DECLARE @Item NVARCHAR(4000)

    SET @tempItemList = REPLACE (@tempItemList, ' ', '')
    SET @i = CHARINDEX(@delimiter, @tempItemList)

    WHILE (LEN(@tempItemList) > 0)
    BEGIN
        IF @i = 0
            SET @Item = @tempItemList
        ELSE
            SET @Item = LEFT(@tempItemList, @i - 1)
        INSERT INTO @IDTable(Item) VALUES(@Item)
        IF @i = 0
            SET @tempItemList = ''
        ELSE
            SET @tempItemList = RIGHT(@tempItemList, LEN(@tempItemList) - @i)
        SET @i = CHARINDEX(@delimiter, @tempItemList)
    END 
    RETURN
END

CROSS APPLY次に、それを使用して参加できます。

SELECT PromotionId, CodeList.Item AS Codes
FROM Promotion p
    CROSS APPLY dbo.Split(Codes, ',') CodeList

編集：これはあなたのデータのフィドルです：http://sqlfiddle.com/#!3/85f8b/1/0

結果：

PROMOTIONID    CODES
  1             a
  1             b
  2             c
  3             d
  3             e
  3             f
于 2012-10-18T12:15:20.447 に答える
2

次のようなXMLでSQLを使用するのはどうですか。

declare @X xml

SET @X= (SELECT CONVERT(xml,'<s id="'+cast(PromotionId as varchar)+'">' + REPLACE(Codes,',','</s><s id="'+cast(PromotionId as varchar)+'">') + '</s>') FROM t1
FOR XML RAW)

SELECT c.value('(@id)[1]','int') as PromotionId, c.value('.','varchar(50)') as Code
FROM @X.nodes('/row/s') T(c)

より効率的かつ高速になります

SQLFiddleデモ

于 2012-10-18T13:08:13.287 に答える
1

T-SQL で物事を分割/連絡する最も速い方法は、XML を使用することだと思います。これが私が使用した解決策です：

;WITH CTE(PromotionID,Codes)
AS
(
    SELECT  PromotionID
           ,CAST(N'<r><![CDATA[' + REPLACE(Codes, ',', ']]></r><r><![CDATA[') + ']]></r>' AS XML) AS Codes
    FROM @SourceTable
)
SELECT  PromotionID
       ,Code
FROM CTE
CROSS APPLY (SELECT DISTINCT RTRIM(LTRIM(Tbl.Col.value('.', 'nvarchar(250)'))) AS Code FROM Codes.nodes('//r') Tbl(Col)) AS List

Common Table Expression を使用して、コードを XML としてキャストしました。次に、一般的な方法で XML を個々の要素に分割しています。完全な動作例は次のとおりです。

SET NOCOUNT ON
GO

DECLARE @SourceTable TABLE
(
    PromotionID INT,
    Codes NVARCHAR(20)
)

INSERT INTO @SourceTable (PromotionID,Codes)
VALUES   (1,'a,b')
        ,(2,'c')
        ,(3,'d,e,f')

;WITH CTE(PromotionID,Codes)
AS
(
    SELECT  PromotionID
           ,CAST(N'<r><![CDATA[' + REPLACE(Codes, ',', ']]></r><r><![CDATA[') + ']]></r>' AS XML) AS Codes
    FROM @SourceTable
)
SELECT  PromotionID
       ,Code
FROM CTE
CROSS APPLY (SELECT DISTINCT RTRIM(LTRIM(Tbl.Col.value('.', 'nvarchar(250)'))) AS Code FROM Codes.nodes('//r') Tbl(Col)) AS List


SET NOCOUNT OFF
GO
于 2012-10-18T12:51:14.583 に答える