1

指定された時間に分割された指定された日付範囲間のピーク時間を計算するプロシージャをTSQLで記述したいと思います。

Start time: 10-02-2012 10:00
End time  : 10-02 2012 11:00
time range: every 5 minutes

したがって、次のようになります。

10:00 range 1  -> 5 peak times
10:05 range 2  -> 11 peak times
.
.
.
11:00 range 11 -> 7 peak times

時間範囲が30分になると、コードは2つの範囲を計算します

インターバルを使用する必要がありますか？どうすればこの問題を解決できますか？ヘルプはありますか？

4

2 に答える 2

1

時間範囲は次のように決定できます。

declare @StartTime as DateTime = '10-02-2012 10:00'
declare @EndTime as DateTime ='10-02-2012 11:00'
declare @TimeRange as Time = '00:05:00.000'

; with TimeRanges as (
  select @StartTime as StartTime, @StartTime + @TimeRange as EndTime
  union all
  select StartTime + @TimeRange, EndTime + @TimeRange
    from TimeRanges
    where EndTime < @EndTime ) -- Corrected.
  select StartTime, EndTime
    from TimeRanges

範囲をサンプル データと結合して、概要を取得します。

declare @StartTime as DateTime = '10-02-2012 10:00'
declare @EndTime as DateTime ='10-02-2012 11:00'
declare @TimeRange as Time = '00:05:00.000'

declare @Samples as Table ( SampleId Int Identity, SampleTime DateTime )
insert into @Samples ( SampleTime ) values
  ( '10-02-2012 9:00' ), ( '10-02-2012 10:00' ), ( '10-02-2012 10:02' ), ( '10-02-2012 10:02' ),
  ( '10-02-2012 10:05' ), ( '10-02-2012 10:20' ), ( '10-02-2012 10:34' ), ( '10-02-2012 11:30' )

; with TimeRanges as (
  select @StartTime as StartTime, @StartTime + @TimeRange as EndTime
  union all
  select StartTime + @TimeRange, EndTime + @TimeRange
    from TimeRanges
    where EndTime < @EndTime ) -- Corrected.
  select StartTime, EndTime, Count( S.SampleId ) as Samples
    from TimeRanges as TR left outer join
      @Samples as S on TR.StartTime <= S.SampleTime and S.SampleTime < TR.EndTime
    group by TR.StartTime, TR.EndTime
于 2012-10-18T20:21:15.380 に答える
0

DATEADD 関数でループを使用します。

http://msdn.microsoft.com/en-us/library/ms186819.aspx

結果の日付が最後より大きくなるまで、「分」間隔を追加し続けます。

編集

BEGIN
-- setup
DECLARE @start DATETIME
DECLARE @end DATETIME
DECLARE @interval INT
DECLARE @samples TABLE (
    [time] DATETIME
)
SET @start = CAST('10-02-2012 10:00' as DATETIME)
SET @end = CAST('10-02-2012 11:00' as DATETIME)
SET @interval = 5
INSERT INTO @samples VALUES 
    ( '10-02-2012 9:00' ), ( '10-02-2012 10:00' ), ( '10-02-2012 10:02' )
    , ( '10-02-2012 10:02' ), ( '10-02-2012 10:05' ), ( '10-02-2012 10:20' )
    , ( '10-02-2012 10:34' ), ( '10-02-2012 11:30' )
-- make the ranges
DECLARE @ranges TABLE (
    [start] datetime
    ,[end] datetime
)
DECLARE @tmp DATETIME
SET @tmp = DATEADD(minute, @interval, @start)
IF @tmp > @end BEGIN SET @tmp = @end END
WHILE @start < @end
    BEGIN
    INSERT INTO @ranges VALUES (@start, @tmp)
    SET @start = @tmp
    SET @tmp = DATEADD(minute, @interval, @start)
    IF @tmp > @end BEGIN SET @tmp = @end END
    END
-- execute the query
SELECT r.[start], r.[end], count(s.[time]) [count]
FROM @ranges r
    LEFT JOIN @samples s 
        ON r.[start] <= s.[time] AND r.[end] > s.[time]
GROUP BY r.[start], r.[end]
END

単純な while ループを使用して、必要な範囲を生成することを提案していました。確かに洗練されていませんが、CTE 再帰クエリ ソリューションよりも単純で理解しやすいと思います。

于 2012-10-18T20:01:09.287 に答える