0

DBD::CSVを使用してcsvデータを表示しています。ファイルに列名が含まれていない場合があるため、手動で定義する必要があります。しかし、ドキュメントに従った後、属性skip_first_rowを機能させる方法に行き詰まりました。私が持っているコードは次のとおりです。

#! perl
use strict;
use warnings;
use DBI;

my $dbh = DBI->connect("dbi:CSV:", undef, undef, {
    f_dir            => ".",
    f_ext            => ".txt/r",
    f_lock           => 2,
    csv_eol          => "\n",
    csv_sep_char     => "|",
    csv_quote_char   => '"',
    csv_escape_char  => '"',
    csv_class        => "Text::CSV_XS",
    csv_null         => 1,
    csv_tables       => {
        info => {
            file => "countries.txt"
        }
    },  
    FetchHashKeyName => "NAME_lc",
}) or die $DBI::errstr;

$dbh->{csv_tables}->{countries} = {
  skip_first_row => 0,
  col_names => ["a","b","c","d"],
};

my $sth = $dbh->prepare ("select * from countries limit 1");
$sth->execute;
while (my @row = $sth->fetchrow_array) {
  print join " ", @row;
  print "\n"
}
print join " ", @{$sth->{NAME}};

countries.txtファイルは次のようになります。

AF|Afghanistan|A|Asia
AX|"Aland Islands"|E|Europe
AL|Albania|E|Europe

しかし、このスクリプトを実行すると、

AX Aland Islands E Europe
AF AFGHANISTAN A ASIA

私はそれがどちらかを返すことを期待しました：

AF AFGHANISTAN A ASIA
a b c d

また

a b c d
a b c d

ここで何が起こっているのか知っていますか？

4

1 に答える 1

0

何らかの理由で、ドキュメントとは異なり、に渡さない限り、テーブルごとの設定は表示されませんconnect。

my $dbh = DBI->connect("dbi:CSV:", undef, undef, {
    f_dir            => ".",
    f_ext            => ".txt/r",
    f_lock           => 2,
    csv_eol          => "\n",
    csv_sep_char     => "|",
    csv_quote_char   => '"',
    csv_escape_char  => '"',
    csv_class        => "Text::CSV_XS",
    csv_null         => 1,
    csv_tables       => {
        countries => {
            col_names => [qw( a b c d )],
        }
    },
    FetchHashKeyName => "NAME_lc",
}) or die $DBI::errstr;

その後、正常に動作します。

my $sth = $dbh->prepare ("select * from countries limit 1");
$sth->execute;

print "@{ $sth->{NAME} }\n";      # a b c d

while (my $row = $sth->fetch) {
    print "@$row\n";              # AF Afghanistan A Asia
}
于 2012-10-22T18:14:17.433 に答える