azure - WindowsAzurePingサイト

Question

WindowsAzureクラウドを使用してサイトを運営しています。20分ごとにサイトにpingを実行する方法はありますか？私のサイトはトラフィックが少ないので、サイトがアプリプールを常に開始および停止するのを停止する必要があります。

Answer 1

pingを実行するようにCronジョブをセットアップできる場合があります。例については、タスク「Cronジョブサービスを使用したWindowsAzureWebサイトでのスケジュール」を確認してください。

Answer 2

完全なクラウド サービス (別名 Web ロール) を使用している場合は、スタートアップ タスクを使用して、アプリケーション プールをシャットダウンしないように設定できます。このスクリプトはそれを実行するだけでなく、私が役立つと思ったその他の IIS 構成の変更もいくつか行います。

@ECHO OFF

@REM A file to flag that this script has already run
@REM because if we run it twice, it errors out and prevents the Azure role from starting properly
@REM %~n0 expands to the name of the currently executing file, without the extension
SET FLAGFILE=c:\%~n0-flag.txt

IF EXIST "%FLAGFILE%" (
  ECHO %FLAGFILE% exists, exiting startup script
  exit /B
) ELSE (
  date /t > %FLAGFILE%
)

@REM Enable IIS compression for application/json MIME type
@REM This will fail the second time you run it on a machine (eg, your desktop). So don't do that. 
%windir%\system32\inetsrv\appcmd.exe set config -section:system.webServer/httpCompression /+"dynamicTypes.[mimeType='application/json',enabled='True']" /commit:apphost
%windir%\system32\inetsrv\appcmd.exe set config -section:system.webServer/httpCompression /+"dynamicTypes.[mimeType='application/json; charset=utf-8',enabled='True']" /commit:apphost

@REM Set IIS to automatically start AppPools
%windir%\system32\inetsrv\appcmd.exe set config -section:applicationPools -applicationPoolDefaults.startMode:AlwaysRunning /commit:apphost

@REM Set IIS to not shut down idle AppPools
%windir%\system32\inetsrv\appcmd set config -section:applicationPools -applicationPoolDefaults.processModel.idleTimeout:00:00:00 /commit:apphost

@REM remove IIS response headers
%windir%\system32\inetsrv\appcmd.exe set config /section:httpProtocol /-customHeaders.[name='X-Powered-By']