1

次のような XML があります。

<V>
  <W>
    <X>1</X> 
  </W>
  <W>
    <Y>1</Y> 
  </W>
  <W>
    <X>1555</X> 
  </W>
  <W>
    <X>1</X> 
  </W>
</V>

私はそれを次のようにしたい：

<entity ID="start">
    <f ID="NewField">0001</f>
    <f ID="NewField">0001</f>
    <f ID="NewField">0002</f>
    <f ID="NewField">0003</f>
</entity>

フィールドが V/W/X の場合NewField、タグ V/W/X が見つかった回数だけ 1 ずつインクリメントする必要があります。V/W/Y についても同様です。

私が使用しているXSLは

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
<entity ID="start">
    <xsl:for-each select="V/W">
        <xsl:if test="X">
            <xsl:variable name="my_var">
                <xsl:value-of select="concat('000',position())"/>
            </xsl:variable>
            <f ID="NewField"><xsl:value-of  select="$my_var"/></f>
        </xsl:if>
        <xsl:if test="Y">
            <xsl:variable name="my_var">
                <xsl:value-of select="concat('000',position())"/>
            </xsl:variable>
            <f ID="NewField"><xsl:value-of  select="$my_var"/></f>
        </xsl:if>
    </xsl:for-each>
</entity>
</xsl:template>
</xsl:stylesheet>

しかし、それは私に次のような間違った結果をもたらします:

<entity ID="start">
  <f ID="NewField">0001</f>
  <f ID="NewField">0002</f> 
  <f ID="NewField">0003</f> 
  <f ID="NewField">0004</f> 
</entity>
4

3 に答える 3

1

XSLT でノードに番号を付けたい場合は、 xsl:number 要素が役立ちます。

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

  <xsl:output indent="yes"/>

  <xsl:template match="/">
    <entity ID="start">
      <xsl:apply-templates select="descendant::X | descendant::Y"/>
    </entity>
  </xsl:template>

  <xsl:template match="X | Y">
    <f ID="NewField"><xsl:number level="any" format="0000"/></f>
  </xsl:template>

</xsl:stylesheet>
于 2010-02-14T16:34:13.663 に答える
0 
<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
  <xsl:template match="V">
    <entity ID="start">
      <xsl:apply-templates select="W/X|W/Y" />
    </entity>
  </xsl:template>

  <xsl:template match="X|Y">
    <f ID="NewField">
      <xsl:variable name="counter" select="
        count(
          parent::W/preceding-sibling::W/*[name() = name(current())]
        ) + 1
      " />
      <xsl:value-of select="format-number($counter, '0000')" />
    </f>
  </xsl:template>

</xsl:stylesheet>

これ：

parent :: W / previous-sibling :: W / * [name（）= name（current（））]

現在の要素と同じ名前の先行するすべての要素を選択します。たとえば、実行ポイントがこのノードにある場合：

<X>1555</X>

1つ上のレベル（parent::W）に移動し、先行するすべて<W>の兄弟を選択します。そのうち、要素の名前は--であるため、名前が-の子（ *）を選択します。XXcurrent()

結果のノードセットがカウントされ、1ずつインクリメントされます。format-number()きれいな出力を生成するために使用されます。

<entity ID="start">
  <f ID="NewField">0001</f>
  <f ID="NewField">0001</f>
  <f ID="NewField">0002</f>
  <f ID="NewField">0003</f>
</entity>
于 2009-08-21T15:15:59.353 に答える
0

count(preceding::X)表現のようなものを探していると思います。もちろん、もっと複雑にして数値のフォーマットに注意したいかもしれませんが、それはあなたが探している出発点のように思えます。

于 2009-08-21T14:25:04.460 に答える