2

Windowsイベントログを読み取ることができるクラスまたは関数はありますか。これは、 eventvwr.mscを開いたときに表示されるログです 。そして、理想的には特定のログ（私の場合はWindowsログの下のアプリケーションログ）を選択し、日付とソースにフィルターを配置します。

4

3 に答える 3

7

Win32_NTLogEventWMIクラスを使用して、Windowsログの内容を読み取ることができます。

このサンプルを試してください

{$APPTYPE CONSOLE}

{$R *.res}

uses
  SysUtils,
  ActiveX,
  ComObj,
  Variants;


procedure  GetLogEvents;
const
  wbemFlagForwardOnly = $00000020;
var
  FSWbemLocator : OLEVariant;
  FWMIService   : OLEVariant;
  FWbemObjectSet: OLEVariant;
  FWbemObject   : OLEVariant;
  oEnum         : IEnumvariant;
  iValue        : LongWord;
begin;
  FSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
  FWMIService   := FSWbemLocator.ConnectServer('localhost', 'root\CIMV2', '', '');
  FWbemObjectSet:= FWMIService.ExecQuery('SELECT Category,ComputerName,EventCode,Message,RecordNumber FROM Win32_NTLogEvent  Where Logfile="System"','WQL',wbemFlagForwardOnly);
  oEnum         := IUnknown(FWbemObjectSet._NewEnum) as IEnumVariant;
  while oEnum.Next(1, FWbemObject, iValue) = 0 do
  begin
    Writeln(Format('Category          %s',[String(FWbemObject.Category)]));
    Writeln(Format('Computer Name     %s',[String(FWbemObject.ComputerName)]));
    Writeln(Format('EventCode         %d',[Integer(FWbemObject.EventCode)]));
    Writeln(Format('Message           %s',[String(FWbemObject.Message)]));
    Writeln(Format('RecordNumber      %d',[Integer(FWbemObject.RecordNumber)]));
    FWbemObject:=Unassigned;
  end;
end;

begin
 try
    CoInitialize(nil);
    try
      GetLogEvents;
    finally
      CoUninitialize;
    end;
 except
    on E:EOleException do
        Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode]));
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
 end;
 Writeln('Press Enter to exit');
 Readln;
end.

その他のサンプルについては、このブログエントリをお試しくださいWMI Tasks using Delphi – Event Logs

于 2012-10-30T15:13:37.140 に答える
3

イベントログの読み取りは、ReadEventLog()関数を使用して実行されます。例については、MSDNを参照してください。

イベント情報のクエリ

于 2012-10-30T17:51:42.113 に答える
2

JVCLJvNTEventLogには、 Windowsイベントログを開いて操作できるという名前のコンポーネントが含まれています。

于 2012-10-30T13:52:19.320 に答える