macos - applescriptを使用してうなり声の通知を出す方法は？

Question

SVNの作業コピーを更新するスクリプトを使用しています。

Growlをインストールしました。スクリプトがSVNの作業コピーの更新を完了したら、Growl通知を送信したいと思います。

私を助けてください。

Answer 1

GoogleとGrowlのサイトで少し検索すれば、問題は解決したかもしれません。

それについて知るためにここをクリックしてください。

または、このコードをAppleスクリプトエディタに直接コピーして貼り付け、どのように機能するかを確認します。

tell application "System Events"
    set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
end tell

if isRunning then
    tell application id "com.Growl.GrowlHelperApp"
        -- Make a list of all the notification types 
        -- that this script will ever send:
        set the allNotificationsList to ¬
            {"Test Notification", "Another Test Notification"}

        -- Make a list of the notifications 
        -- that will be enabled by default.      
        -- Those not enabled by default can be enabled later 
        -- in the 'Applications' tab of the Growl preferences.
        set the enabledNotificationsList to ¬
            {"Test Notification"}

        -- Register our script with growl.
        -- You can optionally (as here) set a default icon 
        -- for this script's notifications.
        register as application ¬
            "Growl AppleScript Sample" all notifications allNotificationsList ¬
            default notifications enabledNotificationsList ¬
            icon of application "Script Editor"

        --       Send a Notification...
        notify with name ¬
            "Test Notification" title ¬
            "Test Notification" description ¬
            "This is a test AppleScript notification." application name "Growl AppleScript Sample"

        notify with name ¬
            "Another Test Notification" title ¬
            "Another Test Notification :) " description ¬
            "Alas — you won't see me until you enable me..." application name "Growl AppleScript Sample"

    end tell
end if

これであなたの質問が解決することを願っています。

Answer 2

私はスクリプトでGrowlNotify（http://growl.info/extras.php#growlnotify）を使用することを本当に好みます。これは、AppleScriptを介した唸り声のより簡単で直接的な方法です。