1

このクエリは、任意の SQL Server データベースのすべてのテーブル/ビューから任意の文字列値 (テーブル名、テーブル データなど) を検索できます。「your text here」に任意の文字列を配置すると、すべてのテーブルから指定された文字列が検索されます。そのデータベースにビューが存在し、

DECLARE @SearchStr nvarchar(100) 
    SET @SearchStr = 'your text here'

DECLARE @Results TABLE(ColumnName nvarchar(370), ColumnValue nvarchar(3630))

SET NOCOUNT ON

DECLARE @TableName nvarchar(256), @ColumnName nvarchar(128), @SearchStr2 nvarchar(110)
SET  @TableName = ''
SET @SearchStr2 = QUOTENAME('%' + @SearchStr + '%','''')

WHILE @TableName IS NOT NULL
BEGIN
    SET @ColumnName = ''
    SET @TableName = 
    (
        SELECT MIN(QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME))
        FROM    INFORMATION_SCHEMA.TABLES
        WHERE       TABLE_TYPE = 'BASE TABLE'
            AND QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME) > @TableName
            AND OBJECTPROPERTY(
                    OBJECT_ID(
                        QUOTENAME(TABLE_SCHEMA) + '.' + QUOTENAME(TABLE_NAME)
                         ), 'IsMSShipped'
                           ) = 0
    )

    WHILE (@TableName IS NOT NULL) AND (@ColumnName IS NOT NULL)
    BEGIN
        SET @ColumnName =
        (
            SELECT MIN(QUOTENAME(COLUMN_NAME))
            FROM    INFORMATION_SCHEMA.COLUMNS
            WHERE       TABLE_SCHEMA    = PARSENAME(@TableName, 2)
                AND TABLE_NAME  = PARSENAME(@TableName, 1)
                AND DATA_TYPE IN ('char', 'varchar', 'nchar', 'nvarchar')
                AND QUOTENAME(COLUMN_NAME) > @ColumnName
        )

        IF @ColumnName IS NOT NULL
        BEGIN
            INSERT INTO @Results
            EXEC
            (
                'SELECT ''' + @TableName + '.' + @ColumnName + ''', LEFT(' + @ColumnName + ', 3630) 
                FROM ' + @TableName + ' (NOLOCK) ' +
                ' WHERE ' + @ColumnName + ' LIKE ' + @SearchStr2
            )
        END
    END 
END

SELECT ColumnName, ColumnValue FROM @Results

しかしprocedures/functions/triggers、SQL Server 2005 にクエリが存在するかどうかだけでなく、特定の文字列を検索するのも好きです。このクエリはこれらの領域を検索しないためです。

4

3 に答える 3

7

プロシージャ/関数/トリガーで指定された文字列を検索します

これは実際にははるかに簡単です。

SELECT OBJECT_NAME(object_id), definition
  FROM sys.sql_modules
 WHERE definition LIKE '%'+@SearchStr+'%'

これを使用する 1 つの方法は、TSQL コードの最後に追加することです。つまり、最後の SELECT を変更します。

SELECT ColumnName, ColumnValue
  FROM @Results
 UNION ALL
SELECT OBJECT_NAME(object_id), definition
  FROM sys.sql_modules
 WHERE definition LIKE '%'+@SearchStr+'%'

個人的には、それらを個別のステートメントとして次々と個別に実行するだけです。

于 2012-11-01T11:04:22.100 に答える
3

ビューsys.sql_modulesを確認してください。

または、SQL Server の 2005 年より前のバージョンでは、syscomments

于 2012-11-01T11:03:17.093 に答える
0

これは、msDB から proc などを検索するのにも役立つクエリであり、SQL Server エージェントのジョブでテーブル/関数/プロシージャ リファレンスが検索されることを意味します。

USE [msdb] 
GO 
SELECT j.job_id, s.srvname, j.name, js.step_id, js.command, j.enabled 
FROM dbo.sysjobs j 
JOIN dbo.sysjobsteps js ON js.job_id = j.job_id  
JOIN master.dbo.sysservers s     ON s.srvid = j.originating_server_id 
WHERE js.command LIKE N'%YOUR TEXT HERE%'

上記の受け入れられた回答のクエリ

SELECT OBJECT_NAME(object_id), definition
FROM sys.sql_modules
WHERE definition LIKE '%'+@SearchStr+'%'

選択したDBのプロシージャ/関数/トリガーで指定されたテキストを見つけるためにのみ機能します。

以下のクエリは、SQL Server エージェント ジョブのジョブ ステータスを確認するために機能します。

SELECT sj.name
   , sja.*
FROM msdb.dbo.sysjobactivity AS sja
INNER JOIN msdb.dbo.sysjobs AS sj ON sja.job_id = sj.job_id

SELECT TOP 10 * FROM msdb.dbo.sysjobhistory

DB 内のテーブルの制約の詳細を検索するクエリ。

SELECT
    FK_Table = FK.TABLE_NAME,
    FK_Column = CU.COLUMN_NAME,
    PK_Table = PK.TABLE_NAME,
    PK_Column = PT.COLUMN_NAME,
    Constraint_Name = C.CONSTRAINT_NAME
FROM
    INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS C
INNER JOIN INFORMATION_SCHEMA.TABLE_CONSTRAINTS FK
    ON C.CONSTRAINT_NAME = FK.CONSTRAINT_NAME
INNER JOIN INFORMATION_SCHEMA.TABLE_CONSTRAINTS PK
    ON C.UNIQUE_CONSTRAINT_NAME = PK.CONSTRAINT_NAME
INNER JOIN INFORMATION_SCHEMA.KEY_COLUMN_USAGE CU
    ON C.CONSTRAINT_NAME = CU.CONSTRAINT_NAME
INNER JOIN (
            SELECT
                i1.TABLE_NAME,
                i2.COLUMN_NAME
            FROM
                INFORMATION_SCHEMA.TABLE_CONSTRAINTS i1
            INNER JOIN INFORMATION_SCHEMA.KEY_COLUMN_USAGE i2
                ON i1.CONSTRAINT_NAME = i2.CONSTRAINT_NAME
            WHERE
                i1.CONSTRAINT_TYPE = 'PRIMARY KEY'
           ) PT
    ON PT.TABLE_NAME = PK.TABLE_NAME
    WHERE PT.table_name = 'Table Name'

SQL ジョブ エージェントの実行中のジョブ ステータスを確認するには、次の手順を実行します。

use msdb                          
go                         
SELECT  j.name JobName            
, STUFF(STUFF(h.run_date,5,0,'-'),8,0,'-') as Date
, CAST(STR(h.run_date, 8, 0) AS DATETIME) + CAST(STUFF(STUFF(RIGHT('000000' + CAST (h.run_time AS VARCHAR(6)), 6),5, 0, ':'), 3, 0, ':') AS DATETIME) AS StartDate
, STUFF(STUFF(RIGHT(REPLICATE('0', 6) + CAST(h.run_duration as varchar(6)), 6), 3, 0, ':'), 6, 0, ':') AS DURATION
, CASE h.run_status               
          WHEN 0 THEN 'failed'           
          WHEN 1 THEN 'Succeded'         
          WHEN 2 THEN 'Retry'            
          WHEN 3 THEN 'Cancelled'        
          WHEN 4 THEN 'In Progress'      
        END AS ExecutionStatus           

FROM    sysjobhistory h           
        INNER JOIN sysjobs j             
            ON j.job_id = h.job_id       
                     WHERE STEP_ID = 0
                     AND CAST(STR(h.run_date, 8, 0) AS DATETIME) + CAST(STUFF(STUFF(RIGHT('000000' + CAST (h.run_time AS VARCHAR(6)), 6),5, 0, ':'), 3, 0, ':') AS DATETIME)>=getdate()-90
                     AND (j.name Like 'DW%' 
                     )
ORDER BY j.name, STUFF(STUFF(h.run_date,5,0,'-'),8,0,'-')

したがって、これは、DB でテキストを検索する人にとって役立ちます。

これは、SQLサーバーでSP /ビュー/トリガーなどの定義を見つけるためのクエリです。

SELECT definition   
FROM sys.sql_modules  
WHERE object_id = OBJECT_ID(N'Object Name Here');

テーブル スキーマを表示するには、F1 を使用できます。完全な詳細については、次のクエリも使用できます。

SELECT DISTINCT C.COLUMN_NAME, C.IS_NULLABLE, C.DATA_TYPE, TC.CONSTRAINT_TYPE, C.COLUMN_DEFAULT
FROM INFORMATION_SCHEMA.COLUMNS AS C
FULL JOIN INFORMATION_SCHEMA.CONSTRAINT_COLUMN_USAGE AS CC ON C.COLUMN_NAME = CC.COLUMN_NAME 
FULL JOIN INFORMATION_SCHEMA.TABLE_CONSTRAINTS AS TC ON CC.CONSTRAINT_NAME = TC.CONSTRAINT_NAME WHERE C.TABLE_NAME = 'Table Name Here';
于 2014-04-04T05:21:46.460 に答える