rebol - Rebol：ビルドマークアップ関数でローカル変数を使用する方法は？

Question

他のビルドマークアップ関数を作成するなど、これを行う方法はありますか？

Answer 1

残念ながら、ビルドマークアップはグローバル変数のみを使用します。リンクテキストによると：タグ内で使用される変数は常にグローバル変数であることに注意してください。

これは、内部オブジェクトを使用してそれを行う少し気難しい方法です（bm-1は問題を示しています：aとbはそれらのグローバル値で出力されます; bm-2は気難しい回避策です）：

a: "global-a"
b: "global-b"


bm-1: func [a b][
      print build-markup "<%a%> <%b%>"
   ]

bm-2: func [a b][
    cont: context [
       v-a: a
       v-b: b
       ]
      print build-markup "<%cont/v-a%> <%cont/v-b%>"
   ]

bm-1 "aaa" "bbb"
bm-2 "aaa" "bbb"

REBOL3には、ビルドマークアップではなく言い換えがあります。それははるかに柔軟です。

Answer 2

ローカルコンテキストを使用できるように、ビルドマークアップ関数にパッチを適用しました。

build-markup: func [
    {Return markup text replacing <%tags%> with their evaluated results.}
    content [string! file! url!]
    /bind obj [object!] "Object to bind"    ;ability to run in a local context
    /quiet "Do not show errors in the output."
    /local out eval value
][
    content: either string? content [copy content] [read content]
    out: make string! 126
    eval: func [val /local tmp] [
        either error? set/any 'tmp try [either bind [do system/words/bind load val obj] [do val]] [
            if not quiet [
                tmp: disarm :tmp
                append out reform ["***ERROR" tmp/id "in:" val]
            ]
        ] [
            if not unset? get/any 'tmp [append out :tmp]
        ]
    ]
    parse/all content [
        any [
            end break
            | "<%" [copy value to "%>" 2 skip | copy value to end] (eval value)
            | copy value [to "<%" | to end] (append out value)
        ]
    ]
    out
]

使用例を次に示します。

>> x: 1 ;global
>> context [x: 2 print build-markup/bind "a <%x%> b" self]
"a 2 b"
>> print build-markup/bind "a <%x%> b" context [x: 2]
"a 2 b"