5

バッチファイルを使用してコマンドプロンプトを複製しようとしています。私の現在のコードは以下に再現されています。

@echo off
title Command Prompt
:LOOP
set /p COMMAND="%CD%>"
title Command Prompt - %COMMAND%
call %COMMAND%
echo.
title Command Prompt
goto LOOP

ただし、問題が1つあります。プログラム（などgpedit.msc）を呼び出している場合、バッチファイルは、プログラムが戻るまで待機してから続行します。プログラムが戻るのを待たずに、通常のコマンドプロンプトが返されます。

コマンドがプログラムであるかどうかをテストして、コマンドを使用できるようにするにはどうすればよいstartですか？

4

1 に答える 1

2

実行可能ファイルで。を検索できますuser32.dll。

@echo off
title Command Prompt
:LOOP
    set /p COMMAND="%CD%>"
    title Command Prompt - %COMMAND%

    call :is_gui %COMMAND%
    if errorlevel 1 (
        call %COMMAND%
    ) else (
        start "" %COMMAND%
    )

    echo.
    title Command Prompt
    goto LOOP

:is_gui app_name
    set app_name=%~1
    set file_app=

    rem Get path of application
    if exist "%app_name%" (
        set file_app=%app_name%
    ) else (
        rem Lookup path of app
        for %%P in (%PATHEXT%) do (
          for %%I in (%1 %1%%P) do (
            if exist "%%~$PATH:I" (
              set file_app=%%~$PATH:I
              goto continue
            )
          )
        )
    )
    :continue
    if "%file_app%"=="" exit /b 1
    find /i "user32.dll" < "%file_app%" >nul 2>&1
    exit /b %errorlevel%
于 2012-11-11T20:07:09.297 に答える