3

こんにちは、SAS でグラフを作成する際に問題が発生しました。私のデータは次のとおりです:日付、comp_1、comp_2、comp_3、total_value。私のデータは日付順にソートされています。変数 comp_ は、特定のデータにおける会社の価値を表します。これは現時点での私のコードです:

proc gplot data=dev2.Actionfinal2;
    plot (comp_1 comp_2 comp_3)*date 
         / overlay areas=3 vaxis=0 to 100000 by 20000;
    symbol1 i=join v= cv= ci=red;
    symbol2 i=join v= cv= ci=blue;
    symbol3 i=join v= cv= ci=green;
run; 
quit;

このグラフは 3 つの企業の値を重ねて表示していますが、これらを積み上げて、各日付の企業の合計値を確認できるようにします。データを再フォーマットする必要がありますか? どのオプションを使用できますか?

4

1 に答える 1

3

3 つの「comp」変数の集計値を使用して、新しい変数を作成する必要があります。このSASの使用上の注意を素晴らしい例とともに参照してください。これで始められるはずです。StackOverflow へようこそ!

更新:問題をよりよく理解していると思います: データを非正規化する必要があります (列を観測値に変換します)。だからこれを試してください：

data test(keep=company value date);
  set dev2.Actionfinal2;
  company = 1; value = comp_1; output;
  company = 2; value = comp_2; output;
  company = 3; value = comp_3; output;
run;

proc sort data=test;
   by date company;
run;

data test2;
   set test;
      by date;
   if first.date then new_y=0;
   new_y + value;
run;

symbol1 i=join v= cv= ci=red;
symbol2 i=join v= cv= ci=blue;
symbol3 i=join v= cv= ci=green;

proc gplot data=test2;
    plot new_y*date=company 
         / areas=3 vaxis=0 to 100000 by 20000;
run; 
quit;
于 2012-11-03T17:14:43.683 に答える