html - 2 つの行と多数の列の Xml からテーブルへの変換のための XSL

Question

私は先週尋ねた質問のバリエーションに取り組もうとしています。

各セクションの最初と最後のページ番号を 2 行のテーブルに出力する必要があります。

2 行のテーブルを Muenchian グループ化メソッドと統合する方法について混乱しています

XSLT 1.0 ソリューションが必要です。以下に1つの解決策がありますが、2行が必要です。

アドバイスやガイダンスをいただければ幸いです。

入力：

<root>
  <page number="1" section="Arsenal">Arsenal</page> 
  <page number="2" section="Arsenal">Arsenal</page> 
  <page number="3" section="Arsenal">Arsenal</page> 
  <page number="4" section="Arsenal">Arsenal</page> 
  <page number="5" section="Arsenal">Arsenal</page> 
  <page number="6" section="Arsenal">Arsenal</page> 
  <page number="7" section="Chelsea">Chelsea</page> 
  <page number="8" section="Chelsea">Chelsea</page> 
  <page number="9" section="Chelsea">Chelsea</page> 
  <page number="10" section="Chelsea">Chelsea</page> 
  <page number="11" section="Chelsea">Chelsea</page> 
  <page number="12" section="Chelsea">Chelsea</page> 
  <page number="13" section="ManUnited">ManUnited</page> 
  <page number="14" section="ManUnited">ManUnited</page> 
  <page number="15" section="ManUnited">ManUnited</page> 
  <page number="16" section="ManUnited">ManUnited</page> 
  <page number="17" section="ManUnited">ManUnited</page> 
  <page number="18" section="ManUnited">ManUnited</page> 
  <page number="19" section="ManCity">ManCity</page> 
  <page number="20" section="ManCity">ManCity</page> 
  <page number="21" section="ManCity">ManCity</page> 
  <page number="22" section="ManCity">ManCity</page> 
  <page number="23" section="ManCity">ManCity</page> 
  <page number="24" section="ManCity">ManCity</page> 
 </root>

出力：

<table>
<tr>
<td>Arsenal</td>
<td></td>
<td>Chelsea</td>
<td></td>
<td>ManU</td>
<td></td>
<td>ManCity</td>
<td></td>
</tr>
<tr>
<td>1</td>
<td>6</td>
<td>7</td>
<td>12</td>
<td>13</td>
<td>18</td>
<td>19</td>
<td>24</td>
</tr>
</table>

これが現在の XSLT ロジックです。

<table>
<tr>
<xsl:apply-templates select="page[generate-id() = generate-id(key('kSection', @section))]"/>
</tr>                       
</table>
</xsl:template> 
<xsl:template match="page">
<td>
<xsl:value-of select="@section"/>
</td>
<td>
<xsl:value-of select="@number"/>
</td>
<td>
<xsl:value-of select="key('kSection', @section)[last()]/@number"/>
</td>
</xsl:template>
</xsl:stylesheet>

よろしくJJ。

score 1 · Accepted Answer

使用する：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" omit-xml-declaration="yes" indent="yes"/>

  <xsl:key name="k" match="page" use="@section"/>

  <xsl:template match="/root">
    <table>
      <tr>
        <xsl:apply-templates select="page[generate-id() = generate-id(key('k', @section))]"/>
      </tr>
      <tr>
        <xsl:apply-templates select="page[generate-id() = generate-id(key('k', @section))]" mode="page"/>
      </tr>
    </table>
  </xsl:template>

  <xsl:template match="page">
    <td>
      <xsl:value-of select="."/>
    </td>
    <td></td>
  </xsl:template>

  <xsl:template match="page" mode="page">
    <td>
      <xsl:value-of select="@number"/>
    </td>
    <td>
      <xsl:value-of select="key('k', @section)[last()]/@number"/>
    </td>
  </xsl:template>

</xsl:stylesheet>

出力：

<table>
  <tr>
    <td>Arsenal</td>
    <td />
    <td>Chelsea</td>
    <td />
    <td>ManUnited</td>
    <td />
    <td>ManCity</td>
    <td />
  </tr>
  <tr>
    <td>1</td>
    <td>6</td>
    <td>7</td>
    <td>12</td>
    <td>13</td>
    <td>18</td>
    <td>19</td>
    <td>24</td>
  </tr>
</table>

score 1 · Accepted Answer

最初にグループ化する必要があり、section次に最初と最後のノードを取得しますfor-each

Group by `section`
  for-each `section`
    if position =1 or position = last
      print it

以下は、xsl 1.0 のグループ化の例のリファレンスです。続行できることを願っています

XSLT は、行セット内の最後のバージョンの要素のみを選択します

**xsltで**

<xsl:key name="k" match="page" use="@section"/>

<xsl:template match="/root">
    <table border="1">
        <tr>
            <xsl:for-each select="page[generate-id() = generate-id(key('k', @section))]">
                <td  colspan="2">
                    <xsl:value-of select="."/>
                </td>
            </xsl:for-each>
        </tr>    
        <tr>
        <xsl:for-each select="page[generate-id() = generate-id(key('k', @section))]">
            <xsl:variable name="key">
                <xsl:value-of select="."/>
            </xsl:variable>
            <xsl:for-each select="../page[@section=$key]">
                <xsl:if test="(position() = 1) or (position() = last())">
                    <td>
                        <xsl:value-of select="current()/@number"/>
                    </td>
                </xsl:if>
            </xsl:for-each>
        </xsl:for-each>
        </tr>
    </table>
</xsl:template>

html - 2 つの行と多数の列の Xml からテーブルへの変換のための XSL

2 に答える 2

Related

Reference