0

私はこれを理解するために今日の午後ずっとSOとグーグルで検索してきました、

PC123などのコンピューター名を入力してコンピューターのCドライブ（\ PC123 \ c $）に接続し、必要なログイン資格情報を使用してWindowsエクスプローラーウィンドウを開くように求める.vbsスクリプトが必要です（これは、すべてのコンピューターで同じ形式）

すなわち：

ユーザー名：PC123 \ PC123_ADMIN

パスワード：PC123＃ADMINpass

これは私が現在持っているものです：

Set objNetwork = WScript.CreateObject("WScript.Network")
objNetwork.MapNetworkDrive "R:", "\\PC123\C$", False, "PC123\PC123_ADMIN",     "PC123#ADMINpass"

これは、R：を目的のPCに接続してマップするために機能しますが、1台の特定のコンピューターにハードコーディングする必要があり、接続したいコンピューターに入ることができません。

可能であれば、さまざまな数のコンピューターに接続する必要があるため、C$のエクスプローラーウィンドウを直接開きたいと思います。

これどうやってするの？

4

2 に答える 2

0

InputBox関数を検索します。値の入力を求められます。例えば

Input = InputBox("Enter your computer name")

マップされたドライブをエクスプローラーで開くには、[実行]を使用します。例えば

Dim oShell
Set oShell = WScript.CreateObject ("WSCript.shell")
oShell.run "start R:"
于 2012-11-08T00:31:28.860 に答える
0

別のオプションはexplorer.exe、UNCパスから直接開始することです（コマンドを実行しているユーザーが共有にアクセスできる場合）。

computer = InputBox("Enter computer name")
CreateObject("WScript.Shell").Run "explorer /e,\\" & computer & "\C$", 1, False

編集：クレデンシャルを渡す必要がある場合は、持っているものに固執し、静的コンピューター名を変数に置き換えます。

computer = InputBox("Enter computer name")
path     = "\\" & computer & "\C$"
username = computer & "\" & computer & "_ADMIN"
password = computer & "#ADMINpass"

Set objNetwork = CreateObject("WScript.Network")
objNetwork.MapNetworkDrive "R:", path, False, username, password

UNCパスの場合と同じ方法で、そのドライブ文字を使用してエクスプローラウィンドウを開くことができます。

CreateObject("WScript.Shell").Run "explorer /e,R:\", 1, False
于 2012-11-08T12:43:57.573 に答える