2

XMLコーディングを以下に示します

<math>
  <mn>
    <mphantom>12</mphantom>
  </mn>
</math>

必要な出力:

<?xml version='1.0' encoding='UTF-8'?>
<math>|phantom1||phantom2|</math>

XSLT が試した:

<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:m="http://www.w3.org/1998/Math/MathML"
  xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
  xmlns:cl="http://xml.cengage-learning.com/cendoc-core"
  xmlns:mml="http://www.w3.org/1998/Math/MathML"
  xmlns:xlink="http://www.w3.org/1999/xlink">
    <xsl:output method="xml" encoding="UTF-8" indent="no" />
    <xsl:strip-space elements="*" />

    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="mn">
        <xsl:variable name="pText" select="." />
        <xsl:variable name="numst" select="2" />
        <xsl:choose>
            <xsl:when test="not(string-length($pText))&gt;0">
                <xsl:value-of select="$pText" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:variable name="ConcatStr" select="substring($pText,$numst)" />
                <xsl:variable name="FinalStr" select="substring-before($pText,$ConcatStr)" />
                <xsl:text disable-output-escaping="yes">|phantom</xsl:text>
                <xsl:value-of select="$FinalStr" />
                <xsl:text disable-output-escaping="yes">|</xsl:text>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template match="mphantom">
        <xsl:apply-templates />
    </xsl:template>

</xsl:stylesheet>

上記の XSLT を使用して変換しましたが、最初の数値しか取得できません。しかし、再帰的に使用する必要があります。XSLT 1.0 を使用しています。よろしくお願いします

4

2 に答える 2

0

Piezメソッドを使用した、より単純で非再帰的なソリューションを次に示します。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="mphantom">
     <math>
     <xsl:variable name="vCur" select="."/>
      <xsl:for-each select=
       "(document('')//node()|document('')//@*|document('')//namespace::*)
          [not(position() > string-length($vCur))]
       ">
        <xsl:value-of select="concat('|', substring($vCur, position(), 1),'|')"/>
      </xsl:for-each>
     </math>
 </xsl:template>
</xsl:stylesheet>

この変換が提供されたXMLドキュメントに適用される場合：

<math>
    <mn>
        <mphantom>12</mphantom>
    </mn>
</math>

必要な正しい結果が生成されます：

<math>|1||2|</math>

II。完全を期すために、XSLT2.0ソリューションを次に示します。

<xsl:stylesheet version="2.0"   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="mphantom">
     <math>
       <xsl:value-of separator="" select=
        "for $i in 1 to string-length()
          return
             concat('|', substring(., $i, 1), '|')
        "/>
     </math>
 </xsl:template>
</xsl:stylesheet>
于 2012-11-09T13:13:44.183 に答える
0

これを試して..

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output indent="yes" omit-xml-declaration="yes" />
<xsl:strip-space elements="*" />

<xsl:template match="@*|node()">
  <xsl:copy>
    <xsl:apply-templates select="@*|node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="mn[mphantom]" name="phant">
  <xsl:param name="chars" select="mphantom" />
  <xsl:value-of select="concat('|phantom',substring($chars,1,1),'|')" />
  <xsl:if test="substring($chars,2)">
    <xsl:call-template name="phant">
      <xsl:with-param name="chars" select="substring($chars,2)" />
    </xsl:call-template>
  </xsl:if>
</xsl:template>

</xsl:stylesheet>
于 2012-11-09T06:55:05.460 に答える