1

Arch Linux の NASM で、文字ゼロ ('0') を 32 ビット変数に追加するにはどうすればよいですか? これを実行したい理由は、1 桁の入力を 1 に設定し、ゼロを追加することで数値 10 を出力できるようにするためです。ゼロを追加する方法を理解する必要があります。

望ましい状況:

Please enter a number: 9
10

このメソッドを使用して、これを実行できるようにしたい:

Please enter a number: 9999999
10000000

これどうやってするの？

前もって感謝します、

ライリーH

4

1 に答える 1

2

ええと、Bo の言うとおりです…でも、私は退屈でした。あなたはこれを簡単な方法（入力を数値に変換し、1を追加してテキストに戻す）に抵抗があるように見えるので、文字を使用してみました。これが私が思いついたものです。恐ろしいですが、「うまくいくようです」。 

; enter a number and add 1 - the hard way!
; nasm -f elf32 myprog.asm
; ld -o myprog myprog.o -melf_i386

global _start

; you may have these in an ".inc" file
sys_exit equ 1
sys_read equ 3
sys_write equ 4
stdin equ 0
stdout equ 1
stderr equ 2
LF equ 10

section .data
    prompt db "Enter a number - not more than 10     digits - no nondigits.", LF
    prompt_size equ $ - prompt
    errmsg db "Idiot human! Follow instructions next time!", LF
    errmsg_size equ $ - errmsg

section .bss
    buffer resb 16
    fakecarry resb 1

section .text
_start:
    nop
    mov eax, sys_write
    mov ebx, stdout
    mov ecx, prompt
    mov edx, prompt_size
    int 80h

    mov eax, sys_read
    mov ebx, stdin
    mov ecx, buffer + 1 ; leave a space for an extra digit in front
    mov edx, 11
    int 80h
    cmp byte [buffer + 1 + eax - 1], LF
    jz goodinput

; pesky user has tried to overflow us!
; flush the buffer, yell at him, and kick him out!
    sub esp, 4 ; temporary "buffer"
flush:
    mov eax, sys_read
    ; ebx still okay
    mov ecx, esp ; buffer is on the stack
    mov edx, 1
    int 80h
    cmp byte [ecx], LF
    jnz flush
    add esp, 4 ; "free" our "buffer"
    jmp errexit

goodinput:
    lea esi, [buffer + eax - 1] ; end of input characters
    mov byte [fakecarry], 1 ; only because we want  to add 1
    xor edx, edx ; count length as we go

next:
; check for valid decimal digit
    mov al, [esi]
    cmp al, '0'
    jb errexit
    cmp al, '9'
    ja errexit

    add al, [fakecarry] ; from previous digit, or first... to add 1
    mov byte [fakecarry], 0 ; reset it for next time
    cmp al, '9' ; still good digit?
    jna nocarry

; fake a "carry" for next digit
    mov byte [fakecarry], 1
    mov al, '0'
    cmp esi, buffer + 1
    jnz nocarry

; if first digit entered, we're done
; save last digit and add one ('1') into the space we left
    mov [esi], al
    inc edx
    dec esi
    mov byte [esi], '1'
    inc edx
    dec esi
    jmp done

nocarry:
    mov [esi], al
    inc edx
    dec esi
    cmp esi, buffer
    jnz next

done:
    inc edx
    inc edx
    mov ecx, esi ; should be either buffer + 1, or buffer
    mov ebx, stdout
    mov eax, sys_write
    int 80h
    xor eax, eax ; claim "no error"

exit:
    mov ebx, eax
    mov eax, sys_exit
    int 80h

errexit:
    mov edx, errmsg_size
    mov ecx, errmsg
    mov ebx, stderr
    mov eax, sys_write
    int 80h
    mov ebx, -1
    jmp exit
;-----------------------------

それはあなたが念頭に置いていたことですか？

于 2012-11-10T14:41:04.140 に答える