4

IS OF TYPEについて読みましたが、TRUE、FALSE、またはNULLを返すはずです。

私には2つのオブジェクトタイプがあります：

CREATE TYPE o1 AS OBJECT ( id NUMBER );
/
CREATE TYPE o2 AS OBJECT ( id NUMBER );
/

以下のコードを実行すると、すべて問題ありません。

DECLARE
  type1 o1;
BEGIN
   type1 := o1(id=>1); 

   if (type1 IS OF (o1)) then
       DBMS_OUTPUT.PUT_LINE('type1 is o1');                    
   END if;  
END;
/

しかし、私が実行しようとすると：

DECLARE
  type1 o1;
BEGIN
   type1 := o1(id=>1); 

   if (type1 IS OF (o2)) then
       DBMS_OUTPUT.PUT_LINE('type1 is o1');                    
   END if;  
END;
/

次の例外が発生しました

Error report:
ORA-06550: line 6, column 21:
PLS-00382: expression is of wrong type
ORA-06550: line 6, column 4:
PL/SQL: Statement ignored
06550. 00000 -  "line %s, column %s:\n%s"
*Cause:    Usually a PL/SQL compilation error.
*Action:

ドキュメントには明確な説明がありませんが、何かが間違ったタイプである場合、例外をキャッチする必要がありますか？または、IF条件でfalseを期待する必要がありますか？

4

1 に答える 1

4

変数を型として宣言した場合、条件をO1使用して、変数が型であるか、またはのサブタイプis of [type]であるかのみをテストできます。以下に例を示します (変数はインスタンス化する必要があります)。 o1o1

 -- base type  
 SQL> create or replace type o1 as object(
  2    prop number
  3  )not final;
  4  /

Type created

-- O1's subtype
SQL> create or replace type o2 under o1(
  2    prop1 number
  3  );
  4  /

-- test if the  l_o1 is of O1 type
SQL> declare
  2    l_o1  o1;
  3  begin
  4    l_o1 := o1(prop=>1);
  5    if l_o1 is of (o1)
  6    then
  7      dbms_output.put_line('Yes');
  8    else
  9      dbms_output.put_line('No');
 10    end if;
 11  end;
 12  /

Yes

PL/SQL procedure successfully completed

-- test if the  l_o1 is of O2 type
SQL> declare
  2    l_o1  o1;
  3  begin
  4    l_o1 := o1(prop=>1);
  5    if l_o1 is of (o2)
  6    then
  7      dbms_output.put_line('Yes');
  8    else
  9      dbms_output.put_line('No');
 10    end if;
 11  end;
 12  /

No

PL/SQL procedure successfully completed


-- test if the  l_o2 is of O2 type

SQL> declare
  2    l_o2  o2;
  3  begin
  4    l_o2 := o2(prop=>1, prop1 => 1);
  5    if l_o2 is of (o2)
  6    then
  7      dbms_output.put_line('Yes');
  8    else
  9      dbms_output.put_line('No');
 10    end if;
 11  end;
 12  /

Yes

PL/SQL procedure successfully completed

更新：

の詳細については、これを参照してis of[type]ください。通常、変数のデータ型はコンパイル時に認識されますが、動的型付けを処理する必要がある場合は、anydata(オブジェクト データ型) を調べることができます。簡単な例を次に示します。

 SQL> declare
  2    l_o1 o1;
  3  
  4    -- Here is a procedure(for the sake of simplicity has not
  5    -- been written as a schema object)
  6    -- that doesn't not know
  7    -- variable of what dada type will be passed in
  8    -- at compile time;
  9    procedure DoSomething(p_var anydata)
 10    is
 11    begin
 12      case p_var.gettypename
 13        when 'HR.O1'
 14        then dbms_output.put_line('O1 data type. Do something');
 15        when 'HR.O2'
 16        then dbms_output.put_line('O2 data type. Do something');
 17      else
 18        dbms_output.put_line('Unknown data type');
 19      end case;
 20    end;
 21  
 22  begin
 23    l_o1 := o1(prop =>  1);
 24    DoSomething(anydata.ConvertObject(l_o1));
 25  end;
 26  /

O1 data type. Do something

PL/SQL procedure successfully completed
于 2012-11-10T19:34:28.153 に答える