4

数字を長さでソートする方法を知っている人はいますか?

例 : (11,111,122,12,2,13,21,15,211,22,213,2004)

ソートされた配列を次のようにしたかった：

11
12
13
15
111
122
2
21
22
213
2004年
4

4 に答える 4

6

目的の出力は、桁数だけでソートするのではなく、最初に最初の桁でソートし、次に長さでソートすることを示しているようです。

あなたが示す望ましい出力は省略され211ているので、私はそれが属する場所にそれを置くだけです。

#!/usr/bin/env perl

use strict;
use warnings;

use Test::More;

my @source = (11, 111, 122, 12, 2, 13, 21, 15, 211, 22, 213, 2004);
my @desired = (11, 12, 13, 15, 111, 122, 2, 21, 22, 211, 213, 2004);

my @sorted =sort {
    substr($a, 0, 1) <=> substr($b, 0, 1) ||
    length($a) <=> length($b) || 
    $a <=> $b # thanks @ikegami
} @source;

is_deeply(\@sorted, \@desired, 'Sorted and desired are the same');
于 2012-11-14T04:10:19.757 に答える
2

いわゆるSchwartzian transformを考えてみましょう。これは、一時的に入力項目に関連付けることで、並べ替えキーの再計算を回避します。

my @sorted =
    map { $_->[0] }
    sort { $a->[1] cmp $b->[1] or $a->[0] <=> $b->[0] }
    map { [ $_ => sprintf "%.1s%08x", $_, length ] }
    @source;
于 2012-11-14T12:22:16.290 に答える
2 
my @sorted =
   sort { substr($a,0,1) <=> substr($b,0,1) || $a <=> $b }
    @unsorted;

あなたが要求した順序を与えます。または多分あなたがしたい

my @sorted =
   sort {  substr($a,0,1) <=> substr($b,0,1)
        || length($a) <=> length($b)
        || $a <=> $b }
   @unsorted;

あなた211が提供した出力に欠けていなければ、どれが欲しいか教えてあげることができます。

于 2012-11-14T04:24:48.620 に答える
1

これはによって提供されますList::UtilsBy::sort_by

use List::UtilsBy qw( sort_by );

my @sorted = sort_by { sprintf "%.1s%08x", $_, length } @source;

これは、他の人が提案した Schwartzian Transform ソリューションとほぼ同じですが、きちんとした抽象化に包まれています。

于 2012-11-15T12:14:52.857 に答える