0

Excel ファイルを解析する Perl スクリプトを作成しています。このスクリプトの目的は、列 1 の各セル値、列 2 の値の数をカウントすることです。

たとえば、次のような Excel ファイルがあります。

12    abc
12    abc
12    efg
12    efg
13    hij
13    hij
13    klm

私のスクリプトは次を返します：

セル値 12 の場合:

2 values "abc", 2 values "efg" and for cell value 13 i have : 2 values "hij" and 1 value "klm".

私のスクリプトは次のようになります (この例は perl doc から取得しました)。

 use Spreadsheet::XLSX;

 my $excel = Spreadsheet::XLSX -> new ('Book1.xlsx');

 foreach my $sheet (@{$excel -> {Worksheet}}) {

    printf("Sheet: %s\n", $sheet->{Name});

    $sheet -> {MaxRow} ||= $sheet -> {MinRow}; 

     foreach my $row ($sheet -> {MinRow} .. $sheet -> {MaxRow}) {

            $sheet -> {MaxCol} ||= $sheet -> {MinCol};

            foreach my $col ($sheet -> {MinCol} ..  $sheet -> {MaxCol}) {

                    my $cell = $sheet -> {Cells} [$row] [$col];

                    if ($cell) {
                        #here I should count the cell values 
                    }
                print $cell;
            }

    }


 }

これまでに perl を使用したことがないため、これを行う方法がわかりません。また、必要なものと正確に一致する例をオンラインで見つけることができません。どんな助けでも大歓迎です。ありがとう

4

2 に答える 2

0

おそらく、次のコメント付きスクリプトが役立ちます。

use strict;
use warnings;
use Spreadsheet::XLSX;
use Data::Dumper;

# No need to iterate through columns, so set val for col 1
my $col1 = 0;
my %hash;

my $excel = Spreadsheet::XLSX->new('Book1.xlsx');

# Just get the first sheet
my $sheet = ${ $excel->{Worksheet} }[0];

# Calculate the range of rows
$sheet->{MaxRow} ||= $sheet->{MinRow};

# Iterate through each row
foreach my $row ( $sheet->{MinRow} .. $sheet->{MaxRow} ) {

    # The cell in column 1
    my $cell = $sheet->{Cells}[$row][$col1];

    if ($cell) {

        # The adjacent cell in column 2
        my $adjacentCell = $sheet->{Cells}[$row][ $col1 + 1 ];

        # Use a hash of hashes
        $hash{ $cell->{Val} }{ $adjacentCell->{Val} }++;
    }
}

# Numerically sort the keys; the value is a hash reference
for my $key1 ( sort { $a <=> $b } keys %hash ) {
    print "For cell value $key1: ";

    # Dereference the hash reference and get the keys/values
    while ( my ( $key2, $val2 ) = each %{ $hash{$key1} } ) {
        print qq{$val2 value(s) "$key2" };
    }
    print "\n";
}

# Show the hash structure
print "\n", Dumper \%hash;

出力：

For cell value 12: 2 value(s) "abc" 2 value(s) "efg" 
For cell value 13: 1 value(s) "klm" 2 value(s) "hij" 

$VAR1 = {
          '13' => {
                    'klm' => 1,
                    'hij' => 2
                  },
          '12' => {
                    'abc' => 2,
                    'efg' => 2
                  }
        };

キー「13」に関連付けられた値を表示するには、次の操作を実行できます。

# Show only the value(s) for key '13'
print "For cell value 13: ";

# Dereference the hash reference for key '13' and get the keys/values
while ( my ( $key2, $val2 ) = each %{ $hash{13} } ) {
    print qq{$val2 value(s) "$key2" };
}

出力：

For cell value 13: 1 value(s) "klm" 2 value(s) "hij"
于 2012-11-14T22:49:45.800 に答える
0

ハッシュを使用します。で数え$hash{$column1}{$column2}++ます。キーを反復処理し、カウントされた値を出力します。はい、列 1、列 2 の値を入力し、ハッシュを反復処理する作業を残しました。

于 2012-11-14T20:07:29.743 に答える