4

私はオラクル10gを使用しています。一時テーブルTEMPがあります。

TEMPの構造は次のとおりです。-

USER COUNT TYPE
---- ----- ----
   1    10   T1
   2    21   T2
   3    45   T1
   1     7   T1
   2     1   T3

すべての型に列名があることを示すクエリが必要です。型には次のような任意の値を指定できT1, T2,..Tn、結果は次のようになります。-

USER T1 T2 T3
---- -- -- --
   1 17  0  0
   2  0 21  1
   3 45  0  0

[ユーザー]列にはすべてのユーザーが表示され、T1, T2列にはタイプの総数が表示されます。

4

3 に答える 3

9

Oracle 10gには関数はありませんでしたが、 ：PIVOTを含む集計を使用して複製できます。CASE

select usr,
  sum(case when tp ='T1' then cnt else 0 end) T1,
  sum(case when tp ='T2' then cnt else 0 end) T2,
  sum(case when tp ='T3' then cnt else 0 end) T3
from temp
group by usr;

SQL FiddlewithDemoを参照してください

Oracle 11g +を使用している場合は、次のPIVOT関数を使用できます。

select *
from temp
pivot
(
  sum(cnt)
  for tp in ('T1', 'T2', 'T3')
) piv

SQL FiddlewithDemoを参照してください

変換する値の数が不明な場合は、次の動的バージョンを生成するプロシージャを作成できます。

CREATE OR REPLACE procedure dynamic_pivot(p_cursor in out sys_refcursor)
as
    sql_query varchar2(1000) := 'select usr ';

    begin
        for x in (select distinct tp from temp order by 1)
        loop
            sql_query := sql_query ||
              ' , sum(case when tp = '''||x.tp||''' then cnt else 0 end) as '||x.tp;

                dbms_output.put_line(sql_query);
        end loop;

        sql_query := sql_query || ' from temp group by usr';

        open p_cursor for sql_query;
    end;
/

次に、コードを実行します。

variable x refcursor
exec dynamic_pivot(:x)
print x

すべてのバージョンの結果は同じです。

| USR | T1 | T2 | T3 |
----------------------
|   1 | 17 |  0 |  0 |
|   2 |  0 | 21 |  1 |
|   3 | 45 |  0 |  0 |

Total編集：フィールドが必要な場合のコメントに基づいて、最も簡単な方法は、次のような別のクエリ内にクエリを配置するSELECTことです。

select usr,
  T1 + T2 + T3 as Total,
  T1,
  T2,
  T3
from
(
  select usr,
    sum(case when tp ='T1' then cnt else 0 end) T1,
    sum(case when tp ='T2' then cnt else 0 end) T2,
    sum(case when tp ='T3' then cnt else 0 end) T3
  from temp
  group by usr
) src;

SQL FiddlewithDemoを参照してください

于 2012-11-16T13:00:08.613 に答える
2

テーブルを作成するためのコードは次のとおりです。

CREATE TABLE TBL_TEMP
(
    USR   NUMBER
   ,CNT   NUMBER
   ,TP    VARCHAR2 (10)
);

INSERT INTO TBL_TEMP VALUES (1,10,'T1');
INSERT INTO TBL_TEMP  VALUES (2,21,'T2');
INSERT INTO TBL_TEMP  VALUES (3,45,'T1');
INSERT INTO TBL_TEMP  VALUES (1,7,'T1');
INSERT INTO TBL_TEMP  VALUES (2,1,'T3');

そして、ここにあなたのリクエストのコードがあります：

  SELECT T1.USR
        ,SUM (T1) T1
        ,SUM (T2) T2
        ,SUM (T3) T3
    FROM (SELECT DISTINCT USR FROM TBL_TEMP) T1
        ,(SELECT T2.USR
                ,DECODE (T2.TP, 'T1', T2.CNT, 0) T1
                ,DECODE (T2.TP, 'T2', T2.CNT, 0) T2
                ,DECODE (T2.TP, 'T3', T2.CNT, 0) T3
            FROM TBL_TEMP T2) T2
   WHERE T1.USR = T2.USR
GROUP BY T1.USR;

そして、結果はあなたが望んでいたものです。

こちらのSQLFiddleLinkで確認してください

于 2012-11-16T08:14:27.063 に答える
0

クエリを確認してください：

SET SERVEROUTPUT ON;
DECLARE
CURSOR V_CUR IS
 SELECT DISTINCT "TYPE" FROM temp_tbl;

V_QUERY CLOB;
V_COLUMNHEADING CLOB;
V_ROW V_CUR%ROWTYPE;
BEGIN
  OPEN V_CUR;
  LOOP
  FETCH V_CUR INTO V_ROW;
  EXIT WHEN V_CUR%NOTFOUND;
    V_COLUMNHEADING:=CONCAT(V_COLUMNHEADING,''''||V_ROW."TYPE"||''' AS "'||V_ROW."TYPE"||'",');
  END LOOP;

  IF NVL(V_COLUMNHEADING,' ') <> ' ' THEN
        V_COLUMNHEADING := SUBSTR(V_COLUMNHEADING,0,LENGTH(V_COLUMNHEADING)-1);
  END IF;

  V_QUERY := CONCAT(V_QUERY,'select * from (select * from temp_tbl)a pivot (sum("COUNT")for "TYPE" in ('||V_COLUMNHEADING||'))b;');
  DBMS_OUTPUT.PUT_LINE(V_QUERY);
END ;

OPEN CUR_TURN_TIME FOR V_QUERY;データを選択するには、の代わりにステートメントを使用します。DBMS_OUTPUT.PUT_LINE(V_QUERY);ここCUR_TURN_TIMEで、はパッケージで宣言されているカーソルです。

于 2012-11-16T11:20:15.250 に答える