0

次のxmlにhref属性を追加する必要がありましたが、すべてのサブプロセスにhref属性があるわけではありません。

<?xml version="1.0"?>
<processes>
    <process nr="1" name="Process1" >
        <subprocess nr="1" name="Subprocess1" href="some/relative/link.html"></subprocess>
        <subprocess nr="2" name="Subprocess2" href="#"></subprocess>
        <subprocess nr="3" name="Subprocess3"></subprocess>
    </process>
</processes>

以下のHTML出力を生成するには、元のXSLで何を変更する必要がありますか？さまざまなhref属性値を処理するにはどうすればよいですか？

XSL：

<xsl:template name="subprocess">
<xsl:call-template name="linking"/>
</xsl:template>
 <xsl:template name="linking">
 <xsl:variable name="processNo" select="@nr"/>   
 <ul class="myframe">
  <xsl:for-each select="subprocess">
    <li>
      <a class="myButton" href="p{$processNo}s{@nr}.html">
        <xsl:value-of select="@nr"/>
        <br/>
        <xsl:value-of select="@name"/>
      </a>
    </li>
  </xsl:for-each>
</ul>
</xsl:template>

HTML：

<ul class="myframe">
    <li><a class="linkButton" href="some/relative/link.html">Subprocess1</a></li>
    <li><a class="noLink" href="#">Subprocess2</a></li>
    <li><a class="myButton" href="p1s3.html">Subprocess3</a></li>
</ul>

したがって、href属性に応じて、異なるCSSクラスも割り当てたいと思います。

ご協力いただきありがとうございます。

4

2 に答える 2

1

使用xsl:chooseとxsl:attribute：

<xsl:template name="linking">
    <xsl:variable name="processNo" select="@nr"/>
    <ul class="myframe">
        <xsl:for-each select="subprocess">
            <li>
                <a>
                    <xsl:choose>
                        <xsl:when test="@href eq '#'">
                            <xsl:attribute name="class" select="'noLink'"/>
                        </xsl:when>
                        <xsl:when test="not(@href)">
                            <xsl:attribute name="class" select="'myButton'"/>
                            <xsl:attribute name="href"
                                select="concat('p',$processNo,'s',@nr,'.html')"/>
                        </xsl:when>
                        <xsl:otherwise>
                            <xsl:sequence select="@href"/>
                        </xsl:otherwise>
                    </xsl:choose>
                    <xsl:value-of select="name()"/>
                </a>
            </li>
        </xsl:for-each>
    </ul>
</xsl:template>
于 2012-11-16T19:28:02.463 に答える
1

これにアプローチする別の方法は、テンプレートとのパターンマッチングの力を利用することです。サブプロセス要素で発生するさまざまな条件に一致する別のテンプレートがあります。

<xsl:template match="subprocess[@href = '#']">

<xsl:template match="subprocess[@href != '' and @href != '#']">

<xsl:template match="subprocess">

次に、これらのそれぞれの中で、リンクテンプレートを呼び出すことができますが、関連するクラス、およびオプションでリンクをパラメーターとして渡します。例えば...

<xsl:template match="subprocess[@href = '#']">
   <xsl:call-template name="linking">
      <xsl:with-param name="class" select="'noLink'"/>
   </xsl:call-template>
</xsl:template>

これが完全なXSLTです

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="process">
      <ul class="myframe">
         <xsl:apply-templates select="subprocess"/>
      </ul>
   </xsl:template>

   <xsl:template match="subprocess[@href = '#']">
      <xsl:call-template name="linking">
         <xsl:with-param name="class" select="'noLink'"/>
      </xsl:call-template>
   </xsl:template>

   <xsl:template match="subprocess[@href != '' and @href != '#']">
      <xsl:call-template name="linking" />
   </xsl:template>

   <xsl:template match="subprocess">
      <xsl:call-template name="linking">
         <xsl:with-param name="class" select="'myButton'"/>
         <xsl:with-param name="link" select="concat('p', ../@nr, 's', @nr, '.html')"/>
      </xsl:call-template>
   </xsl:template>

   <xsl:template name="linking">
      <xsl:param name="class" select="'linkButton'" />
      <xsl:param name="link" select="@href"/>
      <li>
         <a class="{$class}" href="{$link}">
            <xsl:value-of select="@name"/>
         </a>
      </li>
   </xsl:template>
</xsl:stylesheet>

XMLに適用すると、次のように出力されます。

<ul class="myframe">
   <li>
      <a class="linkButton" href="some/relative/link.html">Subprocess1</a>
   </li>
   <li>
      <a class="noLink" href="#">Subprocess2</a>
   </li>
   <li>
      <a class="myButton" href="p1s3.html">Subprocess3</a>
   </li>
</ul>
于 2012-11-16T22:12:31.150 に答える