1

私は映画のxmlファイルに対して次の構造を持っています

<movies>
 <movie>
    <genre>Drama</genre>
    <genre>Thriller</genre>
 </movie>
 ....
</movies>

各映画タグのジャンルのすべての値を選択するためのこのスニペットは機能しませんか？

<xsl:template match="/">
<html>
<body>
<h2>MOVIES</h2>
<table border="1">
<tr bgcolor="#9acd32">
  <th>Genre</th>
</tr>
<xsl:for-each select="movies/movie">
<tr>
  <td>
  <xsl:for-each select="movies/movie/genre">

          <xsl:value-of select="genre"/>

</xsl:for-each>
  </td>

</tr>
</xsl:for-each>
</table>
</body>
</html>
</xsl:template>

</xsl:stylesheet>

それは出力として何も示していません。誰かが間違いを指摘できますか？

4

3 に答える 3

2

ネストされたセレクターが原因で機能していませんxsl:for-each。外側のセレクターは繰り返し処理されるmovies/movieため、内側のセレクターでは既にmovie要素内にありますが、選択していますmovies/movie/genre。それはあなたが探していることを意味します/movies/movie/movies/movie/genre。xsl:value-ofも誤ったセレクターを使用しています。

コードは（テストされていない）次のようになります。

<xsl:for-each select="movies/movie">
<tr>
  <td>
  <!-- context element here is movie -->
  <xsl:for-each select="genre">
      <!-- context element here is genre -->
      <xsl:value-of select="."/>
      <!-- Separate genres with a comma -->
      <xsl:if test="not(position() = last())">, </xsl:if>
  </xsl:for-each>
  </td>
</tr>
</xsl:for-each>

ちなみに（トピック外）、このbgcolor属性はHTML 4で非推奨になりました（ずっと前に）:)style代わりに次を使用する必要があります：

<tr style="background-color: #9acd32;">
于 2012-11-16T21:33:05.543 に答える
2

apply-templatessierrasdetandilの回答はすでに手元にある問題の解決策を示していますが、次の代わりに使用する代替手段を提供したいと思いますfor-each。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html" />

    <xsl:template match="/">
        <html>
            <body>
                <h2>MOVIES</h2>
                    <table>
                        <tr><th>Genre</th></tr>
                        <xsl:apply-templates />
                    </table>
            </body>
        </html>
    </xsl:template>

    <xsl:template match="movies">
        <xsl:apply-templates />
    </xsl:template>

    <xsl:template match="movie">
        <tr>
            <td>
                <xsl:apply-templates />
            </td>
        </tr>
    </xsl:template>

    <xsl:template match="genre">
        <xsl:value-of select="." />
    </xsl:template>

</xsl:stylesheet>
于 2012-11-16T21:50:59.540 に答える
1

これと同じくらい簡単です：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/">
  <table><xsl:apply-templates/></table>
 </xsl:template>
 <xsl:template match="movie">
     <tr>
       <xsl:apply-templates select="node()|@*"/>
     </tr>
 </xsl:template>
 <xsl:template match="genre"><td><xsl:apply-templates/></td></xsl:template>
</xsl:stylesheet>

この変換が提供されたXMLドキュメントに適用される場合：

<movies>
 <movie>
    <genre>Drama</genre>
    <genre>Thriller</genre>
 </movie>
</movies>

必要な正しい結果が生成されます。

<table>
   <tr>
      <td>Drama</td>
      <td>Thriller</td>
   </tr>
</table>
于 2012-11-17T03:09:03.637 に答える