1

私は多くのパワーポイントスライドを持っており、各スライドには多くの線がありますが、それらの線はすべて同じオブジェクトにあります。クリックで各行に表示されるアニメーションを追加したいと思います。

すべての線が独自のオブジェクトになるように、各スライドの線を分割する方法

注、私はパワーポイント2010を使用しています

ありがとう、

AA

4

1 に答える 1

-1

これは完璧ではありません。元のテキストからすべての書式設定を取得するには、さらにコードを追加する必要がありますが、それが始まりです。変更するテキスト ボックス内をクリックし、TEST サブを実行します。好みに合わせて調整したら、プレゼンテーション全体のすべてのテキスト ボックスで機能するように拡張するのはかなり簡単なことです (ただし、表、グラフ、スマート アートなどは対象外です)。

Sub Test()
    TextBoxToLines ActiveWindow.Selection.ShapeRange(1)
End Sub


Sub TextBoxToLines(oSh As Shape)

    Dim oSl As Slide
    Dim oNewShape As Shape
    Dim oRng As TextRange
    Dim x As Long

    With oSh
    Set oSl = .Parent
    With .TextFrame.TextRange
        For x = 1 To .Paragraphs.Count
            Set oRng = .Paragraphs(x)
            Set oNewShape = oSl.Shapes.AddTextbox(msoTextOrientationHorizontal, _
                oRng.BoundLeft, oRng.BoundTop, oRng.BoundWidth, oRng.BoundHeight)
            With oNewShape
                .TextFrame.AutoSize = ppAutoSizeNone
                .Left = oRng.BoundLeft
                .Top = oRng.BoundTop
                .Width = oSh.Width
                .Height = oSh.Height
                With .TextFrame.TextRange
                    .Text = oRng.Text
                    .Font.Name = oRng.Font.Name
                    .Font.Size = oRng.Font.Size
                    ' etc ... pick up any other font formatting you need
                    ' from oRng, which represents the current paragraph of
                    ' the original text
                    ' Bullets, tabs, etc.
                End With
            End With
        Next
    End With
    End With

    oSh.Delete

End Sub
于 2012-11-17T17:41:15.027 に答える