macos - Applescriptを使用して画像のカラープロファイルを取得するには?

Question

)

画像のカラー プロファイルを収集するアップル スクリプトを書きたいのですが、これを行う方法を教えてください。わからない!!

前もって感謝します。

Answer 1

Phil Harvey による ExifToolを使用してメタデータを抽出するのが好きです。これは、メタデータにすばやくアクセスするために作成したサービスです。

on run {input, parameters}
    -- creates a metadata folder in the Documents folder to store results
    set thePath to POSIX path of (path to documents folder) & "metadata" & "/"
    do shell script "mkdir -p " & quoted form of POSIX path of thePath

    set {inputFiles, outputFiles} to {{}, {}}
    repeat with anItem in input
        set end of inputFiles to quoted form of POSIX path of (anItem as text)
        tell application "Finder" to set {name:fileName, name extension:nameExtension} to anItem
        set baseName to text 1 thru ((get offset of "." & nameExtension in fileName) - 1) of fileName
        set end of outputFiles to quoted form of (thePath & baseName & ".txt")
    end repeat

    set {TID, text item delimiters} to {text item delimiters, space}
    set {inputFiles, outputFiles} to {(inputFiles as text), (outputFiles as text)}
    set text item delimiters to TID

    do shell script "exiftool -a " & inputFiles & " -w " & quoted form of (thePath & "%f.txt" as text) & "; open " & outputFiles
end run