0

次のコマンドは、スクリプトファイルに書き込んでいないときは正常に機能しますが、このコマンドをスクリプトファイルに入れると、エラーが表示されます。

nawk 'c-- >0;$0~s{if(b)for(c=b+1;c >1;c--)print r[(NR-c+1)%b];print;c=a}b{r[NR%b]=$0}' b=10 a=10 s="string pattern" file

エラーは次のとおりです。

nawk: syntax error at source line 1 context is >>> ' <<< missing }
nawk: bailing out at source line 1

「スクリプトはどのように見えますか」に対する多くの要求の1つに対するコメント応答の1つは、次のとおりです。

#!/bin/ksh
Stringname=$1
directory=$2
d=$3
Command="nawk 'c-- >0;$0~s{if(b)for(c=b+1;c >1;c--)print r[(NR-c+1)%b];print;c=a}b{r[NR%b]=$0}' b=10 a=10 s=\"$stringname\" $directory"
$Command> $d

コマンド全体をそのような文字列に格納することは非常に困難です。しないでください！それは不必要であり、正しく理解するのは非常に困難です。

#!/bin/ksh
Stringname=$1
directory=$2
d=$3
nawk 'c-- >0;$0~s{if(b)for(c=b+1;c >1;c--)print r[(NR-c+1)%b];print;c=a}b{r[NR%b]=$0}' b=10 a=10 s="$stringname" $directory > $d
4

2 に答える 2

1

一致前にN行、一致後にM行を印刷する問題を解決する最も簡単な方法は、GNUをインストールgrepして次を使用することです。

grep -B $N -A $M 'string pattern' file

それが失敗した場合、これが私が約5年前にその仕事をするためのPerlスクリプトです。試合の前に10行、試合の後に10行を要求すると、いくつかの問題が発生することに注意してください。

  • 7行目での一致（10行前ではない）
  • 30行目と35行目の一致（20〜45行目を印刷する必要があります）
  • 最後の行が65行目（10行後ではない）である60行目での一致
  • 処理するファイルは複数あります。

このコードはそれをすべて処理します。おそらく改善できるでしょう。

#!/usr/bin/perl -w
#
# @(#)$Id: sgrep.pl,v 1.6 2007/09/18 22:55:20 jleffler Exp $
#
# Perl-based SGREP (special grep) command
# 
# Print lines around the line that matches (by default, 3 before and 3 after).
# By default, include file names if more than one file to search.
#
# Options:
# -b n1     Print n1 lines before match
# -f n2     Print n2 lines following match
# -n        Print line numbers
# -h        Do not print file names
# -H        Do     print file names

use strict;
use constant debug => 0;
use Getopt::Std;
my(%opts);

sub usage
{
    print STDERR "Usage: $0 [-hnH] [-b n1] [-f n2] pattern [file ...]\n";
    exit 1;
}

usage unless getopts('hnf:b:H', \%opts);
usage unless @ARGV >= 1;

if ($opts{h} && $opts{H})
{
    print STDERR "$0: mutually exclusive options -h and -H specified\n";
    exit 1;
}

my $op = shift;

print "# regex = $op\n" if debug;

# print file names if -h omitted and more than one argument
$opts{F} = (defined $opts{H} || (!defined $opts{h} and scalar @ARGV > 1)) ? 1 : 0;
$opts{n} = 0 unless defined $opts{n};

my $before = (defined $opts{b}) ? $opts{b} + 0 : 3;
my $after  = (defined $opts{f}) ? $opts{f} + 0 : 3;

print "# before = $before; after = $after\n" if debug;

my @lines = (); # Accumulated lines
my $tail  = 0;  # Line number of last line in list
my $tbp_1 = 0;  # First line to be printed
my $tbp_2 = 0;  # Last line to be printed

# Print lines from @lines in the range $tbp_1 .. $tbp_2,
# leaving $leave lines in the array for future use.
sub print_leaving
{
    my ($leave) = @_;
    while (scalar(@lines) > $leave)
    {
        my $line = shift @lines;
        my $curr = $tail - scalar(@lines);
        if ($tbp_1 <= $curr && $curr <= $tbp_2)
        {
            print "$ARGV:" if $opts{F};
            print "$curr:" if $opts{n};
            print $line;
        }
    }
}

# General logic:
# Accumulate each line at end of @lines.
# ** If current line matches, record range that needs printing
# ** When the line array contains enough lines, pop line off front and,
#    if it needs printing, print it.
# At end of file, empty line array, printing requisite accumulated lines.

while (<>)
{
    # Add this line to the accumulated lines
    push @lines, $_;
    $tail = $.;

    printf "# array: N = %d, last = $tail: %s", scalar(@lines), $_ if debug > 1;

    if (m/$op/o)
    {
        # This line matches - set range to be printed
        my $lo = $. - $before;
        $tbp_1 = $lo if ($lo > $tbp_2);
        $tbp_2 = $. + $after;
        print "# $. MATCH: print range $tbp_1 .. $tbp_2\n" if debug;
    }

    # Print out any accumulated lines that need printing
    # Leave $before lines in array.
    print_leaving($before);
}
continue
{
    if (eof)
    {
        # Print out any accumulated lines that need printing
        print_leaving(0);
        # Reset for next file
        close ARGV;
        $tbp_1 = 0;
        $tbp_2 = 0;
        $tail  = 0;
        @lines = ();
    }
}
于 2012-11-19T20:00:10.730 に答える
1

nawk -f fileただの代わりにスクリプトを実行しようとしているに違いありません./file。

于 2012-11-20T01:15:18.720 に答える