10

このスレッドでは、最後のスレッドを参照しています。XSLTを使用してXMLをCSVに変換します-動的列。

参照されたスレッドのXSLTスクリプトは正常に機能しますが、大きなXMLドキュメントではパフォーマンスが良くありません。次に、最終的なCSVファイルを出力する別のXSLTスクリプトを出力するXSLTスクリプトを作成します。

質問：

最初のXSLTスクリプトを作成するにはどうすればよいですか？出力は次のようになります。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>

<xsl:template match="/*">
    <xsl:text>Name;</xsl:text>
    <xsl:text>Brother;</xsl:text>
    <xsl:text>Sister</xsl:text>
    <-- this part is dynamic -->
    <xsl:apply-templates select="Person" />
</xsl:template>

<xsl:template match="Person">
    <xsl:value-of select="Name" />
    <xsl:value-of select="Brother" />
    <xsl:value-of select="Sister" />
    <-- this part is dynamic too -->
    <xsl:text>&#10;</xsl:text>
</xsl:template>
</xsl:stylesheet>

入力XMLファイルは、参照されるスレッドと同じです。

<Person>
    <Name>John</Name>
    <FamilyMembers>
        <FamilyMember>
            <Name>Lisa</Name>
            <Type>Sister</Type>
        </FamilyMember>
        <FamilyMember>
            <Name>Tom</Name>
            <Type>Brother</Type>
        </FamilyMember>
    </FamilyMembers>
</Person>
<Person>
    <Name>Daniel</Name>
    <FamilyMembers>
        <FamilyMember>
            <Name>Peter</Name>
            <Type>Father</Type>
        </FamilyMember>
    </FamilyMembers>
</Person>

異なるタイプ要素ごとに、結果のXSLTスクリプトに次のような1行が含まれている必要があります。

<xsl:text>Type;</xsl:text>
4

3 に答える 3

18

<xsl:element>別のXSLTを出力するXSLTを作成するには、たとえば、を使用して出力要素を生成する必要があります。

<xsl:element name="xsl:text">

または、<xsl:namespace-alias>リテラルの結果要素を使用する場合に使用します。XSLT仕様には例があります。

<xsl:stylesheet
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:fo="http://www.w3.org/1999/XSL/Format"
  xmlns:axsl="http://www.w3.org/1999/XSL/TransformAlias">

<xsl:namespace-alias stylesheet-prefix="axsl" result-prefix="xsl"/>

<xsl:template match="/">
  <axsl:stylesheet>
    <xsl:apply-templates/>
  </axsl:stylesheet>
</xsl:template>

<axsl:...>スタイルシートの要素はすべて<xsl:...>出力になります。

于 2012-11-20T12:36:00.800 に答える
1

2つの外部フェーズのソリューション（実行されるスタイルシートを書き込むスタイルシートを意味する）ではなく、大規模でより優れたパフォーマンスを発揮するバージョンのTimのソリューションの方が適していると思います。「大きなXMLドキュメント」を入力として、このソリューションのパフォーマンスを測定してください。

このXSLT1.0スタイルシート...

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" />

<xsl:key name="kTypes" match="Type" use="." />  
<xsl:variable name="distinct-types"
  select="/*/Person/FamilyMembers/FamilyMember/Type[
  generate-id()=generate-id(key('kTypes',.)[1])]" />

<xsl:template match="/">
  <xsl:value-of select="'Name;'" />
  <xsl:for-each select="$distinct-types">
    <xsl:value-of select="." />
    <xsl:if test="position() &lt; last()">
      <xsl:value-of select="';'" />
    </xsl:if>  
  </xsl:for-each>
  <xsl:value-of select="'&#x0A;'" />
  <xsl:apply-templates select="*/Person" />
</xsl:template>

<xsl:template match="Person">
  <xsl:value-of select="concat(Name,';')" />
  <xsl:variable name="family" select="FamilyMembers/FamilyMember" />
  <xsl:for-each select="$distinct-types">
    <xsl:variable name="type" select="string(.)" />
    <xsl:value-of select="$family/self::*[Type=$type]/Name" />
    <xsl:if test="position() &lt; last()">
      <xsl:value-of select="';'" />
    </xsl:if>  
  </xsl:for-each>
  <xsl:value-of select="'&#x0A;'" />
</xsl:template>

</xsl:stylesheet>

...この入力（または他の入力を大規模に効率的に変換します）...

<t>
<Person>
    <Name>John</Name>
    <FamilyMembers>
        <FamilyMember>
            <Name>Lisa</Name>
            <Type>Sister</Type>
        </FamilyMember>
        <FamilyMember>
            <Name>Tom</Name>
            <Type>Brother</Type>
        </FamilyMember>
    </FamilyMembers>
</Person>
<Person>
    <Name>Daniel</Name>
    <FamilyMembers>
        <FamilyMember>
            <Name>Peter</Name>
            <Type>Father</Type>
        </FamilyMember>
    </FamilyMembers>
</Person>
</t>

...そしてテキストを生成します...

Name;Sister;Brother;Father
John;Lisa;Tom;
Daniel;;;Peter
于 2012-11-20T13:13:06.367 に答える
0

ここで、別のXSLT変換のスタイルシートを生成するXSLT変換の実際の例を参照してください。

http://dnovatchev.wordpress.com/2006/10/21/a-stylesheet-to-write-xslt-code/

于 2012-11-20T13:43:32.203 に答える