4

単純なタイプを作成します。

create or replace TYPE SIMPLE_TYPE AS OBJECT (ID NUMBER(38), NAME VARCHAR2(20));

簡単なテスト：

DECLARE
   TYPE ObjectList IS TABLE OF SIMPLE_TYPE;
   tmp SIMPLE_TYPE := SIMPLE_TYPE(1, 'a');
   o ObjectList := new ObjectList(SIMPLE_TYPE(2, 'a'), SIMPLE_TYPE(3, 'a'));
BEGIN
   IF tmp.EXISTS(tmp) THEN
    dbms_output.put_line('OK, exists.');
   END IF;
END;

例外が発生します：PLS-00302：コンポーネント'EXISTS'を宣言する必要があります

しかし、この例は機能します：

DECLARE
   TYPE NumList IS TABLE OF INTEGER;
   n NumList := NumList(1,3,5,7);
BEGIN
   n.DELETE(2);
   IF n.EXISTS(1) THEN
      dbms_output.put_line('OK, element #1 exists.');
   END IF;
   IF n.EXISTS(3) = FALSE THEN
      dbms_output.put_line('OK, element #2 has been deleted.');
   END IF;
   IF n.EXISTS(99) = FALSE THEN
      dbms_output.put_line('OK, element #99 does not exist at all.');
   END IF;
END;

SIMPLE_TYPEタイプでEXISTSメソッドを実装することは可能ですか？

4

2 に答える 2

8

ドキュメントに記載されているように、EXISTS(）コレクション内の番号付きエントリの存在をテストします。つまりarray.exists(3)、の3番目の要素が設定されていることを表明しarrayます。

最初の例で実行しようとしているのは、インスタンスtmpがの要素と一致するかどうかをテストすることObjectListです。10g以降、MEMBER OF構文を使用してこれを実行できます。残念ながら、その作業を行うには、MAPメソッドを宣言する必要があります。メソッドはかなり不格好で、オブジェクトに多くの属性があるとかなり煩わしくなります。

SQL> create or replace type simple_type as object
  2       ( id number
  3         , name varchar2(30)
  4         , map member function compare return varchar2);
  5  /

Type created.

SQL>
SQL> create or replace type body simple_type as
  2       map member function compare return varchar2
  3       is
  4          return_value integer;
  5       begin
  6          return to_char(id, '0000000')||name;
  7       end compare;
  8  end;
  9  /

Type body created.

SQL>

例を実行しています...

SQL> set serveroutput on size unlimited
SQL>
SQL> declare
  2      type objectlist is table of simple_type;
  3      tmp simple_type := simple_type(1, 'a');
  4      o objectlist := new objectlist(simple_type(2, 'a'), simple_type(3, 'a'));
  5  begin
  6      if tmp MEMBER OF o then
  7          dbms_output.put_line('ok, exists.');
  8      else
  9          dbms_output.put_line('search me');
 10      end if;
 11  end;
 12  /
search me

PL/SQL procedure successfully completed.

SQL>
于 2009-08-30T07:03:33.790 に答える
3 
tmp SIMPLE_TYPEE := SIMPLE_TYPE(1, 'a');

…

IF tmp.EXISTS(tmp) THEN

tmpとしてSIMPLE_TYPEではなく、として宣言しObjectListます。

SIMPLE_TYPEコレクションではなく、スカラー型です。

o.EXISTSおそらくあなたは代わりにチェックしたかったのですか（これはObjectList）？

アップデート：

EXISTSコレクションに適用されると、引数として整数インデックスを取り、このインデックスを持つ要素が存在するかどうかをチェックします（その値ではありません）。

それがテーブルに存在することを確認SIMPLE_TYPE(1, 'a')するには、次のようにする必要があります。

ObjectList辞書で作成：

CREATE TYPE ObjectList IS TABLE OF SIMPLE_TYPE;

SELECTクエリを発行します。

DECLARE
        tmp SIMPLE_TYPE := SIMPLE_TYPE(1, 'a');
        o ObjectList := new ObjectList(SIMPLE_TYPE(2, 'a'), SIMPLE_TYPE(3, 'a'));
        myid INT;
BEGIN
        SELECT  1
        INTO    myid
        FROM    TABLE(o) q
        WHERE   SIMPLE_TYPE(q.id, q.name) = tmp
                AND rownum = 1;
        IF (myid = 1) THEN
                dbms_output.put_line('OK, exists.');
        END IF;
END;
于 2009-08-28T15:38:54.313 に答える