4

これは私が見逃している単純なことですが、ネストされたループのために、必要な方法で機能していないように感じます。これは私がどこかでやってのけた単純なスクリプトであり、さらにテストできるように少し変更しました。基本的には、ホストを閉じるまで、遅延が発生するたびにホストにpingを実行しますが、失敗した応答はログに記録されます。すべてが機能しますが、私の一生の間、forループで使用されている名前を更新する方法を理解できません。

@echo off
setlocal enabledelayedexpansion

:: ** Enter name to identify host in log **
set name1=Test 1
set name2=Test 2
set name3=Test 3

:: ** Enter IP or HOSTNAME to test against **
set hostIP1=1.1.1.1
set hostIP2=2.2.2.2
set hostIP3=3.3.3.3

:: ** Enter Delay in milliseconds between each test **
set delayMS=2000


title -DO NOT CLOSE- Ping Test
echo DO NOT CLOSE
echo Ping Test


:loop
set namecount=1
for %%x in (%hostIP1% %hostIP2% %hostIP3%) do (
set pingline=1
set pingname=name!namecount!
for /f "delims=" %%A in ('ping -n 1 -w 2000 -l 255 %%x') do (
    if !pingline! equ 2 (
        set logline=!date! !time! "%%A" - %%x !%pingname%!
        echo !logline! | find "TTL=">nul || echo !logline! >> pinglog.txt
        )
    set /a pingline+=1
    )
set /a namecount+=1
)
sleep -m %delayMS%
goto loop

通常は別の言語を使用しますが、あらゆる種類のWindowsサーバーで機能するものが必要です。これが最も確実な方法のようです。ありがとう

4

1 に答える 1

0

これは正しくありません:

!%pingname%!

これを試して：

!Pingname!

私はあなたのコードを試すことはできませんが、他の小さな修正を加えました:

（更新しました）

 @echo off
setlocal enabledelayedexpansion

:: ** Enter name to identify host in log **
set "name1=Test 1"
set "name2=Test 2"
set "name3=Test 3"

:: ** Enter IP or HOSTNAME to test against **
set "hostIP1=1.1.1.1"
set "hostIP2=2.2.2.2"
set "hostIP3=3.3.3.3"

:: ** Enter Delay in milliseconds between each test **
set /A "delayMS=2000"


title -DO NOT CLOSE- Ping Test
Echo DO NOT CLOSE
Echo Ping Test

:loop
set /A "namecount=1"
for %%x in (%hostIP1% %hostIP2% %hostIP3%) do (
    set /A "pingline=1"
    call set "pingname=%%name!namecount!%%"
    for /f "delims=" %%A in ('ping -n 1 -w 2000 -l 255 %%x') do (
        if !pingline! equ 2 (
            set "logline=%date% !time! %%A - %%x !pingname!"
            (echo !logline! | find "TTL=">nul) || (echo !logline! >> "pinglog.txt")
        )
        set /a "pingline+=1"
    )
    set /a "namecount+=1"
)
sleep -m %delayMS%
goto :loop
于 2012-11-22T17:51:46.760 に答える