2 つの日付の時差を計算する際に、いくつかの問題に直面しています。
私が欲しいのは、私には2つの日付があるということです
@StartDate = '10/01/2012 08:40:18.000'
@EndDate='10/04/2012 09:52:48.000'
したがって、2 つの日付の差hh:mm:ssは です72:42:30。
T-SQL クエリでこの結果を取得するにはどうすればよいですか?
質問する
197383 次
14 に答える
59
declare @StartDate datetime, @EndDate datetime
select @StartDate = '10/01/2012 08:40:18.000',@EndDate='10/04/2012 09:52:48.000'
select convert(varchar(5),DateDiff(s, @startDate, @EndDate)/3600)+':'+convert(varchar(5),DateDiff(s, @startDate, @EndDate)%3600/60)+':'+convert(varchar(5),(DateDiff(s, @startDate, @EndDate)%60)) as [hh:mm:ss]
このクエリは役に立ちます。
于 2012-11-27T06:26:46.727 に答える
9
最も効率的ではないかもしれませんが、これはうまくいくでしょう:
declare @StartDate datetime, @EndDate datetime
select @StartDate = '10/01/2012 08:40:18.000',@EndDate='10/04/2012 09:52:48.000'
select convert(varchar(5),DateDiff(s, @startDate, @EndDate)/3600)+':'+convert(varchar(5),DateDiff(s, @startDate, @EndDate)%3600/60)+':'+convert(varchar(5),(DateDiff(s, @startDate, @EndDate)%60))
2 つの select を実行できる場合は、datediff を 1 回しか実行しないため、これの方が適切です。
declare @StartDate datetime, @EndDate datetime
select @StartDate = '10/01/2012 08:40:18.000',@EndDate='10/04/2012 09:52:48.000'
declare @Sec BIGINT
select @Sec = DateDiff(s, @startDate, @EndDate)
select convert(varchar(5),@sec/3600)+':'+convert(varchar(5),@sec%3600/60)+':'+convert(varchar(5),(@sec%60))
于 2012-11-27T06:00:07.480 に答える
8
これを関数にするというアイデアが気に入っているので、再利用可能になり、クエリが読みやすくなります。
--get the difference between two datetimes in the format: 'h:m:s'
CREATE FUNCTION getDateDiff(@startDate DATETIME, @endDate DATETIME)
RETURNS VARCHAR(10)
AS BEGIN
DECLARE @seconds INT = DATEDIFF(s, @startDate, @endDate)
DECLARE @difference VARCHAR(10) =
CONVERT(VARCHAR(4), @seconds / 3600) + ':' +
CONVERT(VARCHAR(2), @seconds % 3600 / 60) + ':' +
CONVERT(VARCHAR(2), @seconds % 60)
RETURN @difference
END
使用法：
DECLARE @StartDate DATETIME = '10/01/2012 08:40:18.000'
DECLARE @endDate DATETIME = '10/04/2012 09:52:48.000'
SELECT dbo.getDateDiff(@startDate, @endDate) AS DateDifference
結果：
DateDifference
1 73:12:30
パディングを追加すると、結果が読みやすくなり、フォーマットが常に になりhh:mm:ssます。たとえば、SQL Server 2012 以降でこれを行う方法は次のとおりです。
--get the difference between two datetimes in the format: 'hh:mm:ss'
CREATE FUNCTION getDateDiff(@startDate DATETIME, @endDate DATETIME)
RETURNS VARCHAR(10)
AS BEGIN
DECLARE @seconds INT = DATEDIFF(s, @startDate, @endDate)
DECLARE @difference VARCHAR(10) =
FORMAT(@seconds / 3600, '00') + ':' +
FORMAT(@seconds % 3600 / 60, '00') + ':' +
FORMAT(@seconds % 60, '00')
RETURN @difference
END
2 桁を超える長さの場合、時間はクリップされないことに注意してください。したがって、1 時間は と表示され01:00:00、100 時間は と表示されます。100:00:00
于 2017-01-09T16:49:44.927 に答える
4
暗黙的な型キャストに反対しない場合は、これに代わる解決策を提供します。より良いフォーマットで読みやすくなっていますか？あなたが裁判官になります。
DECLARE @StartDate datetime = '10/01/2012 08:40:18.000'
,@EndDate datetime = '10/04/2012 09:52:48.000'
SELECT
STR(ss/3600, 5) + ':' + RIGHT('0' + LTRIM(ss%3600/60), 2) + ':' + RIGHT('0' + LTRIM(ss%60), 2) AS [hh:mm:ss]
FROM (VALUES(DATEDIFF(s, @StartDate, @EndDate))) seconds (ss)
于 2014-03-14T16:33:14.593 に答える
1
これを試してください：
declare @StartDate datetime, @EndDate datetime
select @StartDate = '2016-05-04 10:23:41.083', @EndDate='2016-05-04 10:25:26.053'
select CAST(DateDiff(MI, @startDate, @EndDate)/60 AS varchar)+':'+Cast(DateDiff(MI, @startDate, @EndDate)%60 AS varchar)+':'+cast(DateDiff(s, @startDate, @EndDate)%60 AS varchar) as [hh:mm:ss]
于 2016-05-09T06:29:03.880 に答える
0
これらを見てください。読みやすくするために括弧を使用しなかったので、乗算は加算または減算の前に行われることを忘れないでください。
以下の両方が戻ります：
hr mins sec timediff
73 12 30 73:12:30
これは、サブクエリを使用せず、最も読みやすく、理解しやすいように記述されています。
declare @StartDate datetime,
@EndDate datetime
set @StartDate = '10/01/2012 08:40:18.000'
set @EndDate = '10/04/2012 09:52:48.000'
select datediff(hour, @StartDate, @EndDate) hr,
datediff(minute, @StartDate, @EndDate)
- datediff(hour, @StartDate, @EndDate) * 60 mins,
datediff(second, @StartDate, @EndDate)
- (datediff(minute, @StartDate, @EndDate) * 60) sec,
cast(datediff(hour, @StartDate, @EndDate) as varchar)+':'+
cast(datediff(minute, @StartDate, @EndDate)
- datediff(hour, @StartDate, @EndDate) * 60 as varchar)+':'+
cast(datediff(second, @StartDate, @EndDate)
- (datediff(minute, @StartDate, @EndDate) * 60) as varchar) timediff
これは、データが多い場合にパフォーマンスが向上するバージョンです。サブクエリが必要です。
declare @StartDate datetime,
@EndDate datetime
set @StartDate = '10/01/2012 08:40:18.000'
set @EndDate = '10/04/2012 09:52:48.000'
select s.seconds / 3600 hrs,
s.seconds / 60 - (seconds / 3600 ) * 60 mins,
s.seconds - (s.seconds / 60) * 60 seconds,
cast(s.seconds / 3600 as varchar) + ':' +
cast((s.seconds / 60 - (seconds / 3600 ) * 60) as varchar) + ':' +
cast((s.seconds - (s.seconds / 60) * 60) as varchar) timediff
from (select datediff(second, @StartDate, @EndDate) as seconds) s
于 2012-11-27T07:05:01.447 に答える
0
それはスクリプト書き込みコピーです。次にスクリプトファイルに書き込み、必要なフィールドを変更して出力します
DECLARE @Sdate DATETIME, @Edate DATETIME, @Timediff VARCHAR(100)
SELECT @Sdate = '02/12/2014 08:40:18.000',@Edate='02/13/2014 09:52:48.000'
SET @Timediff=DATEDIFF(s, @Sdate, @Edate)
SELECT CONVERT(VARCHAR(5),@Timediff/3600)+':'+convert(varchar(5),@Timediff%3600/60)+':'+convert(varchar(5),@Timediff%60) AS TimeDiff
于 2014-03-06T10:36:42.810 に答える
0
キーフィールドで結合された別々のテーブルにあるフィールド間の時間差を収集しようとしていたときに、今日この投稿に出くわしました。これは、そのような努力のための作業コードです。(SQL 2010 でテスト済み) 私の元のクエリは、共通のキーフィールドで 6 つのテーブルを共同結合したことに注意してください。以下のコードでは、他のテーブルを削除して、読者を混乱させないようにしています。
クエリの目的は、変数 CreatedUTC と BackupUTC の差を計算することです。差は日数で表され、フィールドは「DaysActive」と呼ばれます。
declare @CreatedUTC datetime
declare @BackupUtc datetime
SELECT TOP 500
table02.Column_CreatedUTC AS DeviceCreated,
CAST(DATEDIFF(day, table02.Column_CreatedUTC, table03.Column_EndDateUTC) AS nvarchar(5))+ ' Days' As DaysActive,
table03.Column_EndDateUTC AS LastCompleteBackup
FROM
Operations.table01 AS table01
LEFT OUTER JOIN
dbo.table02 AS table02
ON
table02.Column_KeyField = table01.Column_KeyField
LEFT OUTER JOIN
dbo.table03 AS table03
ON
table01.Column_KeyField = table03.Column_KeyField
Where table03.Column_EndDateUTC > dateadd(hour, -24, getutcdate()) --Gathers records with an end date in the last 24 hours
AND table02.[Column_CreatedUTC] = COALESCE(@CreatedUTC, table02.[Column_CreatedUTC])
AND table03.[Column_EndDateUTC] = COALESCE(@BackupUTC, table03.[Column_EndDateUTC])
GROUP BY table03.Column_EndDateUTC, table02.Column_CreatedUTC
ORDER BY table02.Column_CreatedUTC ASC, DaysActive, table03.Column_EndDateUTC DESC
出力は次のようになります。
[DeviceCreated]..[DaysActive]..[LastCompleteBackup]
---------------------------------------------------------
[2/13/12 16:04]..[463 Days]....[5/21/13 12:14]
[2/12/13 22:37]..[97 Days].....[5/20/13 22:10]
于 2013-05-22T00:11:09.493 に答える