3

マクロで条件付き書式を実行しています（他の書式と一緒に常に新しい生のエクスポートに繰り返し適用しているため）。

目的：セルJ（n）のテキストが「アクティビティなし」である行を強調表示します

現在使用しているもの：

    With Cells
.FormatConditions.Add Type:=xlExpression, Formula1:= _
    "=($J1=""No Activity"")"
    With .FormatConditions(.FormatConditions.Count)
        .SetFirstPriority
        With .Interior
            .PatternColorIndex = xlAutomatic
            .Color = 7405514
            .TintAndShade = 0
        End With
        StopIfTrue = False
    End With
End With

...これはうまく機能します。上記は、グーグル検索と元々私に与えられた記録を使用してクリーンアップされました：

    Cells.Select
Selection.FormatConditions.Add Type:=xlExpression, Formula1:= _
    "=($N1=""No Activity"")"
Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority
With Selection.FormatConditions(1).Interior
    .PatternColorIndex = xlAutomatic
    .ThemeColor = xlThemeColorAccent4
    .TintAndShade = 0.599963377788629
End With
Selection.FormatConditions(1).StopIfTrue = False

だから私はすべての誇りと達成感を感じていました...しかし、列J（上記）のセルにセルのテキストの任意の場所に「引用」が含まれている行（別の色）も強調表示したいと思います。

条件付き書式としてそれを行うマクロを記録したとき、それは私にとって実際には何も明確にしませんでした:(わかりました、それはそれを悪化させました）

    Selection.FormatConditions.Add Type:=xlTextString, String:="Quote", _
    TextOperator:=xlContains
Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority
With Selection.FormatConditions(1).Interior
    .PatternColorIndex = xlAutomatic
    .ThemeColor = xlThemeColorAccent1
    .TintAndShade = 0.399945066682943
End With
Selection.FormatConditions(1).StopIfTrue = False

私はそれがどのように変化するべきかを理解していません

Type:=xlExpression, Formula1:= _
"=($J1=""No Activity"")"

すべてのアイデアは大歓迎です！

4

1 に答える 1

3

これはExcel2010で機能します。

With Cells
    .FormatConditions.Add Type:=xlExpression, Formula1:= _
      "=($J1=""No Activity"")"
    With .FormatConditions(.FormatConditions.Count)
        .SetFirstPriority
        With .Interior
            .PatternColorIndex = xlAutomatic
            .Color = 7405514
            .TintAndShade = 0
        End With
        StopIfTrue = False
    End With

    .FormatConditions.Add Type:=xlExpression, Formula1:= _
      "=ISNUMBER(SEARCH(""*quote*"",$J1))"
    With .FormatConditions(.FormatConditions.Count)
        .SetFirstPriority
        With .Interior
            .PatternColorIndex = xlAutomatic
            .Color = 4405514
            .TintAndShade = 0
        End With
        StopIfTrue = False
    End With
End With

明らかに、2番目のセクションの色を変更する必要がありますFormatConditions.Add。

編集：セル内のどこかで「引用」を探していることに気付いたので、元の投稿からコードを更新しました。

于 2012-11-27T23:53:34.063 に答える