0

のクラスを持つこのスパン要素がありますautbib-pc-bold-italic

<span class="autbib-pc-bold-italic">autbib</span>

@class 属性値に基づいて要素タグを作成したい:

私の出力は次のようになります。

<autbib><pc><bold><italic>autbib</italic></bold></pc></autbib>

ここに私のxslテンプレートがあります:

<xsl:template match="span[contains(@class,'autbib')]">
    <xsl:call-template name="pbib.loop">
        <xsl:with-param name="count" select="count(tokenize(@class, '-'))"/>
        <xsl:with-param name="class" select="tokenize(@class, '-')"/>
    </xsl:call-template>
</xsl:template>

<xsl:template name="pbib.loop">
    <xsl:param name="index" select="1" />
    <xsl:param name="count" select="count(tokenize(@class, '-')) + 1"/>
    <xsl:param name="class" select="tokenize(@class, '-')"/>
    <xsl:element name="{$class[1]}">
       <xsl:if test="not($index = $count)">
            <xsl:element name="{$class[$index]}">
                <xsl:apply-templates/>
            </xsl:element>
       </xsl:if>
    </xsl:element>

    <xsl:if test="not($index = $count)">
        <xsl:call-template name="pbib.loop">
            <xsl:with-param name="index" select="$index + 1" />
        </xsl:call-template>
    </xsl:if>
</xsl:template>

そして、間違っているこの出力があります：

<autbib>
    <pc>autbib</pc>
    <bold>autbib</bold>
    <italic>autbib</italic>
</autbib>

この出力が必要です：

<autbib>
    <pc>
        <bold>
            <italic>autbib</italic>
        </bold>
    </pc>
</autbib>

私の問題は、xsl:apply-templateタグが互いにラップするようにどこに配置すればよいかわからないことです。

4

1 に答える 1

0

これが私の提案です：

<xsl:stylesheet 
  version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">

<xsl:output indent="yes"/>

<xsl:template match="span[contains(@class,'autbib')]">
  <xsl:param name="classes" select="tokenize(@class, '-')"/>
  <xsl:choose>
    <xsl:when test="not($classes[1])">
      <xsl:apply-templates/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:element name="{$classes[1]}">
        <xsl:apply-templates select=".">
          <xsl:with-param name="classes" select="$classes[position() gt 1]"/>
        </xsl:apply-templates>
      </xsl:element>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

</xsl:stylesheet>

入力を変換するSaxon 9.4を使用

<span class="autbib-pc-bold-italic">autbib</span>

結果に

<autbib>
   <pc>
      <bold>
         <italic>autbib</italic>
      </bold>
   </pc>
</autbib>
于 2012-11-28T12:52:04.490 に答える