1

この質問では、条件付きインクリメントを実行する方法を尋ねました。提供された回答は機能しましたが、巨大なデータセットではうまくスケーリングできません。

入力:

<Users>
    <User>
        <id>1</id>
        <username>jack</username>
    </User>
    <User>
        <id>2</id>
        <username>bob</username>
    </User>
    <User>
        <id>3</id>
        <username>bob</username>
    </User>
    <User>
        <id>4</id>
        <username>jack</username>
    </User>
</Users>

望ましい出力 (最適な時間複雑度で):

<Users>
   <User>
      <id>1</id>
      <username>jack01</username>
   </User>
   <User>
      <id>2</id>
      <username>bob01</username>
   </User>
   <User>
      <id>3</id>
      <username>bob02</username>
   </User>
   <User>
      <id>4</id>
      <username>jack02</username>
   </User>
</Users>

この目的のために、

  • 入力をユーザー名でソート
  • ユーザーごとに
    • 以前のユーザー名が現在のユーザー名と等しい場合
      • インクリメントカウンターと
      • ユーザー名を「$username$counter」に設定します
    • それ以外は
      • カウンターを1に設定
  • (再度 ID でソート -要件なし)

何かご意見は？

4

3 に答える 3

2

これはちょっと醜く、私は を使用するxsl:for-eachのが好きではありませんが、先行する兄弟を使用するよりも高速である必要があり、2 パスのアプローチは必要ありません。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
  <xsl:key name="count" match="User" use="username" />

  <xsl:template match="Users">
    <Users>
      <xsl:for-each select="User[generate-id()=generate-id(key('count',username)[1])]">
        <xsl:for-each select="key('count',username)">
          <User>
            <xsl:copy-of select="id" />
            <username>
              <xsl:value-of select="username" />
              <xsl:number value="position()" format="01"/>
            </username>
          </User>
        </xsl:for-each>
      </xsl:for-each>
    </Users>
  </xsl:template>
</xsl:stylesheet>

後で ID でソートする必要がある場合は、2 パス テンプレートにラップできます。

<xsl:stylesheet version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   xmlns:msxsl="urn:schemas-microsoft-com:xslt">
  <xsl:key name="count" match="User" use="username" />

  <xsl:template match="Users">
    <xsl:variable name="pass1">
      <xsl:for-each select="User[generate-id()=generate-id(key('count',username)[1])]">
        <xsl:for-each select="key('count',username)">
          <User>
            <xsl:copy-of select="id" />
            <username>
              <xsl:value-of select="username" />
              <xsl:number value="position()" format="01"/>
            </username>
          </User>
        </xsl:for-each>
      </xsl:for-each>
    </xsl:variable>

    <xsl:variable name="pass1Nodes" select="msxsl:node-set($pass1)" />

    <Users>
      <xsl:for-each select="$pass1Nodes/*">
        <xsl:sort select="id" />
        <xsl:copy-of select="." />
      </xsl:for-each>
    </Users>
  </xsl:template>
</xsl:stylesheet>
于 2012-12-05T16:22:38.413 に答える
1

この変換は、指定された目的の結果を正確に生成し、効率的です（O（N））：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kUserByName" match="User" use="username"/>
 <xsl:key name="kUByGid" match="u" use="@gid"/>

 <xsl:variable name="vOrderedByName">
  <xsl:for-each select=
  "/*/User[generate-id()=generate-id(key('kUserByName',username)[1])]">
     <xsl:for-each select="key('kUserByName',username)">
       <u gid="{generate-id()}" pos="{position()}"/>
     </xsl:for-each>
  </xsl:for-each>
 </xsl:variable>

  <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="username/text()">
     <xsl:value-of select="."/>
     <xsl:variable name="vGid" select="generate-id(../..)"/>

     <xsl:for-each select="ext:node-set($vOrderedByName)[1]">
      <xsl:value-of select="format-number(key('kUByGid', $vGid)/@pos, '00')"/>
     </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

提供されたXMLドキュメントに適用する場合：

<Users>
    <User>
        <id>1</id>
        <username>jack</username>
    </User>
    <User>
        <id>2</id>
        <username>bob</username>
    </User>
    <User>
        <id>3</id>
        <username>bob</username>
    </User>
    <User>
        <id>4</id>
        <username>jack</username>
    </User>
</Users>

必要な正しい結果が生成されます。

<Users>
   <User>
      <id>1</id>
      <username>jack01</username>
   </User>
   <User>
      <id>2</id>
      <username>bob01</username>
   </User>
   <User>
      <id>3</id>
      <username>bob02</username>
   </User>
   <User>
      <id>4</id>
      <username>jack02</username>
   </User>
</Users>
于 2012-12-06T13:08:42.173 に答える
1

これはわずかな違いですが、効率が大幅に向上する可能性はありません

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
   <xsl:output method="xml" indent="yes"/>
   <xsl:key name="User" match="User" use="username" />

   <xsl:template match="username/text()">
      <xsl:value-of select="." />
      <xsl:variable name="id" select="generate-id(..)" />
      <xsl:for-each select="key('User', .)">
         <xsl:if test="generate-id(username) = $id">
            <xsl:number value="position()" format="01"/>
         </xsl:if>
      </xsl:for-each>
   </xsl:template>

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

これが行っているのは、ユーザーをユーザー名でグループ化するためのキーを定義することです。次に、ユーザー名要素ごとに、そのユーザー名のキーの要素を調べ、一致するものが見つかったときに位置を出力します。

このアプローチのわずかな利点の1つは、同じ名前のユーザーレコードのみを表示することです。同じ名前の膨大な数がない場合、これはより効率的かもしれません。

于 2012-12-05T17:26:56.027 に答える