regex - ファイルからバージョン番号を取得するための Perl 正規表現

Question

次のようなファイルがあります。

app.version.code=1
app.version.major=1
app.version.minor=0
app.version.buildnumber=0

を出力する Perl スクリプトを実行したいと考えています<app.version.major>.<app.version.minor>.<app.version.buildnumber>。この場合、1.0.0 が出力されます。私は現在 Perl に非常に慣れておらず、正規表現とスクリプトを作成するのに苦労しています。何か案は？

Answer 1

次のようなものを使用できます。

perl -F= -lane '$h{$F[0]}=$F[1]; 
  END { print join ".", @h{ glob "app.version.{major,minor,buildnumber}" } }' filename

Answer 2

cat > ver.txt
app.version.code=1
app.version.major=1
app.version.minor=0
app.version.buildnumber=0
^d

cat> ver.pl
#!/usr/bin/perl -w

use strict;
use warnings;

my ($ma,$mi,$bi)=(0,0,0);
while(<>){ 
  if(/^app\.version\.(.*)$/) { 
    if( $1 =~ /^major=(\d+)$/ ){$ma=$1}
    elsif( $1 =~ /minor=(\d+)$/ ){$mi=$1}
    elsif( $1 =~ /buildnumber=(\d+)$/ ) {$bi=$1}
  }
} 

print "$ma.$mi.$bi\n";
^d

./ver.pl < ver.txt 
1.0.0

Answer 3

別のオプションは次のとおりです。

use strict;
use warnings;

my %ver;

while (<>) {
    $ver{$1} = $2 if /(major|minor|number)=(\d+)$/;
}

print "$ver{major}.$ver{minor}.$ver{number}\n";

データセットへの出力：

1.0.0

Answer 4

VersionXtrct.pl:

    #!/usr/bin/perl

    use strict;

    my $inFile = $ARGV[0];

    open(INHANDLE, "<$inFile") || die("Could not open file");

    my @fileLines = <INHANDLE>;

    my $fileText = join("", @fileLines);

    my $major;
    my $minor;
    my $build;

    if($fileText =~ m/app\.version\.major=(.+)\n/) { $major = $1; }

    if($fileText =~ m/app\.version\.minor=(.+)\n/) { $minor = $1; }

    if($fileText =~ m/app\.version\.buildnumber=(.+)\n/) { $build = $1; }

    my $version = $major.".".$minor.".".$build;

print "\nversion = ".$version;

    exit(0);

データが input.txt というファイルにあると仮定して、次を実行します。

VersionXtrct.pl input.txt

Answer 5

前回の試行では、任意の順序を想定していませんでした。これは期待どおりに動作するはずです。

#!/usr/bin/env perl

use strict;
use warnings;

use 5.010;

my %version;

while (<DATA>) {
  given ($_) {
    $version{major}       = $1 when /app\.version\.major=(\d+)/;
    $version{minor}       = $1 when /app\.version\.minor=(\d+)/;
    $version{buildnumber} = $1 when /app\.version\.buildnumber=(\d+)/;
  }
}

say join ".", @version{qw/major minor buildnumber/};

__DATA__
app.version.code=1
app.version.major=1
app.version.minor=0
app.version.buildnumber=0