2

ここからfreebaseでjsonを取得しています（注意してください。これは、を使用せずに数回しかリクエストできません&key=your-key）。

応答を次のようなものに変換したいと思います。

    ({:case "Roe v. Wade", :plaintiffs ("Norma McCorvey"), :defendants ("Henry Wade"), :court "Supreme Court of the United States", :subjects ("Abortion" "Privacy"), :article "http://wp/en/68493"} ...)

clojure.data.json/read-stringを使用した後に思いついたコードは次のとおりです。

    (defn extract-data [case]
      {:case (case "name")
       :plaintiffs (flatten (map #(get % "parties") (filter (fn [p] (some #(= (% "id") "/en/plaintiff") (p "role")))
                                                           (case "/law/legal_case/parties"))))
       :defendants (flatten (map #(get % "parties") (filter (fn [p] (some #(= (% "id") "/en/defendant") (p "role")))
                                                           (case "/law/legal_case/parties"))))
       :court (get-in case ["court" 0 "name"])
       :subjects (map #(% "name") (case "subject"))
       :article (get-in case ["/common/topic/article" 0 "source_uri" 0])})

    (def response (-> query-uri
                       java.net.URL.
                       slurp
                       json/read-str))
    (def case-data (map extract-data (response "result")))

extract-dataは非常に複雑に見えますが、これを行うためのより良い方法はありますか？これはcore.logicを使用できる場合ですか？もしそうなら、どのように？

4

2 に答える 2

2

別のクエリシステム（zip-filters、core.logic、datomicのコレクションに関するデータログなど）を見ることができます。または、独自のアドホックなものをロールします。

(defn select [x path]
  (if-let [[p & ps] (seq path)]
    (if (fn? p)
      (mapcat #(select % ps) (filter p x))
      (recur (get x p) ps))
    x))

(def mapping
  {:case ["name"]
   :plaintiffs ["/law/legal_case/parties"
                #(= (get-in % ["role" 0 "id" 0]) "/en/plaintiff")
                "parties"]
   :defendants ["/law/legal_case/parties"
                #(= (get-in % ["role" 0 "id" 0]) "/en/defendant")
                "parties"]
   :court ["court" 0 "name" 0]
   :subjects ["subject" (constantly true) "name"]
   :article ["/common/topic/article" 0 "source_uri" 0]})

(defn extract-data [x mapping]
  (into {}
    (for [[k path] mapping]
      [k (if (some fn? path) (select x path) (get-in x path))])))

そして、（map＃（extract-data％mapping）results）がトリックを実行する必要があります

=> (extract-data (first result) mapping)
{:case "Roe v. Wade", :plaintiffs ("Norma McCorvey"), :defendants ("Henry Wade"), :court "Supreme Court of the United States", :subjects ("Abortion" "Privacy"), :article "http//wp/en/68493"}

このタイプのコード（クエリインタープリター）は脆弱である可能性があるため、必ずテストスイートを用意してください。

于 2012-12-07T14:38:04.490 に答える
0

スペクターがお手伝いします。

(ns stackoverflow-answer.core
  (:require [com.rpl.specter :refer :all]))

; your example data
(def case {"name" "Roe v. Wade"
           "/law/legal_case/parties" [{"role" [{"id" "/en/plaintiff"}]
                                       "parties" ["Norma McCorvey"]}
                                      {"role" [{"id" "/en/defendant"}]
                                       "parties" ["Henry Wade"]}]
           "court" [{"name" "Supreme Court of the United States"}]
           "subject" [{"name" "Abortion"}
                      {"name" "Privacy"}]
           "/common/topic/article" [{"source_uri" ["http://wp/en/68493"]}]})

(defn specter-extract [case]
  {:case (case "name")
   :plaintiffs (select ["/law/legal_case/parties"
                        ALL
                        (selected? "role" ALL "id" (pred= "/en/plaintiff"))
                        "parties"
                        ALL]
                       case)
   ; etc
   })

使用法：

stackoverflow-answers.core=> (specter-extract case)
{:case "Roe v. Wade", :plaintiffs ["Norma McCorvey"]}
于 2019-07-05T10:18:48.243 に答える